3.0 Welk deel van de ingezette uren personeel is door PNIL?

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• Inhuurovereenkomst
• Onverplaatsbaar artefact
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 3.0
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT ?Periode 
12    (?vestiging AS ?Indeling)
13    (SUM(?uren * ?pnil) AS ?Ingezette_uren_PNIL)
14    (SUM(?uren * ?pil) AS ?Ingezette_uren_PIL)
15	( IF(SUM(?uren) = 0, "Ongedefinieerd",
16      ROUND( (100 * SUM(?uren * ?pnil) / SUM(?uren)) * 100 ) / 100)
17  	  AS ?Procent_ingezette_uren_PNIL )
18
19{
20    #BIND(2024 AS ?jaar)            
21    VALUES ?kw { 1 2 3 4 0 }
22
23    BIND( xsd:date(CONCAT(STR(?jaar), "-",
24                IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
25            )) AS ?start_periode )
26    BIND( xsd:date(CONCAT(STR(?jaar), "-",
27                IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
28            )) AS ?eind_periode )
29    BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
30
31
32    VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomst onz-pers:InhuurOvereenkomst onz-pers:UitzendOvereenkomst}
33    
34    ?overeenkomst 
35        a ?type_overeenkomst ; # personeel in loondienst (arbeidsovereenkomst) en personeel niet in loondienst (inhuur- en uitzendovereenkomst)
36        onz-pers:heeftOpdrachtnemer ?persoon ;
37        onz-g:hasPart ?overeenkomst_afspraak .
38    ?overeenkomst_afspraak
39        a onz-pers:WerkOvereenkomstAfspraak ;
40        onz-g:startDatum ?start_afspraak .
41    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
42    FILTER(?start_afspraak <= ?eind_periode && ((?eind_afspraak >= ?start_periode) || (!BOUND(?eind_afspraak))))
43
44    ?overeenkomst_afspraak onz-g:isAbout ?locatie_afspraak .
45    ?locatie_afspraak a onz-g:StationaryArtifact .
46
47    
48    ?inzet
49        a onz-pers:GewerktePeriode ;
50        onz-g:definedBy ?overeenkomst ;
51        onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
52        onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?uren .
53    OPTIONAL{ ?inzet onz-g:hasPerdurantLocation ?locatie_werk }
54    BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
55    FILTER(?start_inzet >= ?start_periode && ?start_inzet <= ?eind_periode)
56    FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
57
58    # Bepaal de locatie voor uren. Gebruik urenregistratie. Als die geen locatie bevat, gebruik locatie van contract
59    BIND(IF(!BOUND(?locatie_werk), ?locatie_afspraak, ?locatie_werk) AS ?locatie)
60    
61	  ?locatie a onz-g:StationaryArtifact ;
62	           onz-g:partOf* ?vestiging_uri .
63      ?vestiging_uri a onz-org:Vestiging .
64      {  
65        	?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
66        	?vest_nr a onz-org:Vestigingsnummer ;
67            onz-g:hasDataValue ?vestiging .
68      } UNION {
69        	# Includeer ook de organisatie als geheel en label deze als vestiging
70        	?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
71        	BIND("Totaal organisatie" AS ?vestiging)
72      }
73
74    
75	BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomst, 1, 0) AS ?pil)
76    BIND(IF (?pil = 0, 1, 0) AS ?pnil)
77
78}
79GROUP BY ?Periode ?vestiging 
80ORDER BY ?Periode ?vestiging 
81