3.4. Wat is verhouding tussen uitbesteed werk en vast personeel?

Concepten

• Grootboekpost
• Grootboekrubriek

Relaties

• deel van
• deel van

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 3.4
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
6PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
7PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
8
9SELECT ("Uitbesteed werk vs vast personeel" AS ?Kental) ?Arbeidsintensiteit
10
11WHERE {
12  {
13    SELECT
14      (
15        IF(
16          BOUND(?vastpersoneel_totaal) && (?vastpersoneel_totaal != 0),
17          ROUND((xsd:decimal(?uitbesteedwerk_totaal) / xsd:decimal(?vastpersoneel_totaal)) * 100) / 100,
18          "Ongedefinieerd"
19        ) AS ?Arbeidsintensiteit
20      )
21    WHERE {
22      {
23        SELECT ((COALESCE(?vast_prismant,0) + COALESCE(?vast_rgs,0)) AS ?vastpersoneel_totaal) ((COALESCE(?uitb_prismant,0) + COALESCE(?uitb_rgs,0)) AS ?uitbesteedwerk_totaal)
24        WHERE {
25
26          {
27            SELECT
28              (SUM(?q_vastpersoneel)  AS ?vast_prismant)
29              (SUM(?q_uitbesteedwerk) AS ?uitb_prismant)
30            WHERE {
31              #BIND(2024 AS ?jaar)
32              BIND(STRDT(CONCAT(STR(?jaar),"-01-01"), xsd:date) AS ?startperiode)
33              BIND(STRDT(CONCAT(STR(?jaar),"-12-31"), xsd:date) AS ?eindperiode)
34
35              {
36                SELECT DISTINCT ?rubriek WHERE {
37                  ?rubriek a onz-fin:Grootboekrubriek .
38                  FILTER(STRSTARTS(STR(?rubriek), STR(onz-fin:)))
39                  FILTER(REGEX(STRAFTER(STR(?rubriek), STR(onz-fin:)), "^[0-9]{6}$"))
40                }
41              }
42
43              BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
44
45              ?grootboek_post a onz-fin:Grootboekpost ;
46                              onz-g:partOf ?rubriek ;
47                              onz-g:hasDate ?datum ;
48                              onz-fin:heeftGeldBedrag ?geld_bedrag .
49
50              FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
51
52              # Prismant
53              BIND(
54                IF(
55                  STRSTARTS(?rubriekCode, "411") ||
56                  STRSTARTS(?rubriekCode, "412") ||
57                  STRSTARTS(?rubriekCode, "413") ||
58                  STRSTARTS(?rubriekCode, "414") ||
59                  STRSTARTS(?rubriekCode, "415") ||
60                  STRSTARTS(?rubriekCode, "416") ||
61                  STRSTARTS(?rubriekCode, "419") ||
62                  STRSTARTS(?rubriekCode, "420") ||
63                  STRSTARTS(?rubriekCode, "422"),
64                  ?geld_bedrag, 0
65                ) AS ?q_vastpersoneel
66              )
67
68              BIND(
69                IF(
70                  STRSTARTS(?rubriekCode, "417") ||
71                  STRSTARTS(?rubriekCode, "418"),
72                  ?geld_bedrag, 0
73                ) AS ?q_uitbesteedwerk
74              )
75            }
76          }
77
78          {
79            SELECT
80              (SUM(?q_vastpersoneel_rgs)  AS ?vast_rgs)
81              (SUM(?q_uitbesteedwerk_rgs) AS ?uitb_rgs)
82            WHERE {
83              #BIND(2024 AS ?jaar)
84              BIND(STRDT(CONCAT(STR(?jaar),"-01-01"),xsd:date) AS ?startperiode)
85              BIND(STRDT(CONCAT(STR(?jaar),"-12-31"),xsd:date) AS ?eindperiode)
86              
87              # RGS
88              VALUES (?rubriek ?soort) {
89                (onz-fin:WPer "P")
90                (onz-fin:WKprKuw "Q")
91              }
92
93              ?grootboek_post a onz-fin:Grootboekpost ;
94                              onz-g:partOf* ?rubriek ;
95                              onz-g:hasDate ?datum ;
96                              onz-fin:heeftGeldBedrag ?geld_bedrag .
97
98              FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
99
100              BIND(IF(?soort = "P", ?geld_bedrag, 0) AS ?q_vastpersoneel_rgs)
101              BIND(IF(?soort = "Q", ?geld_bedrag, 0) AS ?q_uitbesteedwerk_rgs)
102            }
103          }
104        }
105      }
106    }
107  }
108}
109