5.2. Wat is het aantal cliënten per financieringsstroom?

Concepten

• Forensische indicatiestelling
• Indicatiebesluit
• Mens
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• Wmo-indicatie
• Zorgkantoor regio
• Zvw-indicatie

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 5.2
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9
10SELECT ?Periode
11  (?vestiging AS ?Indeling)
12  (IF(?vestiging = "Totaal organisatie", "", SAMPLE(?zk_regio_code)) AS ?Zorgkantoorregio_code)
13  (COUNT(DISTINCT IF(BOUND(?wlz), ?client, ?unbound)) AS ?Wlz)
14  (COUNT(DISTINCT IF(BOUND(?zvw), ?client, ?unbound)) AS ?Zvw)
15(COUNT(DISTINCT IF(BOUND(?wmo), ?client, ?unbound)) AS ?Wmo)
16  (COUNT(DISTINCT IF(!BOUND(?zvw) && !BOUND(?wlz) && !BOUND(?wmo), ?client, ?unbound)) AS ?Overig)
17WHERE {
18#  BIND(2024 AS ?jaar)
19  VALUES ?kw {
20    1 2 3 4 0
21  }
22
23  BIND(
24    xsd:date(CONCAT(STR(?jaar), "-",
25      IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
26    ))
27    AS ?peildatum_eerder
28  )
29  BIND(
30    xsd:date(CONCAT(STR(?jaar), "-",
31      IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
32    ))
33    AS ?peildatum_later
34  )
35  BIND(IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode)
36
37  {
38    ?indicatie a onz-zorg:IndicatieBesluit
39  } UNION {
40    ?indicatie a onz-zorg:ForensischeIndicatieStelling
41  }
42
43  ?indicatie onz-g:isAbout ?client .
44  ?client a onz-g:Human .
45
46  ?indicatie ^onz-g:definedBy ?zorgproces .
47  ?zorgproces
48    onz-g:hasPerdurantLocation ?locatie ;
49    onz-g:startDatum ?start_zorgproces .
50  OPTIONAL {
51    ?zorgproces onz-g:eindDatum ?eind_zorgproces .
52  }
53
54  FILTER (
55    ?start_zorgproces <= ?peildatum_later &&
56    (!BOUND(?eind_zorgproces) || ?eind_zorgproces >= ?peildatum_eerder)
57  )
58
59  OPTIONAL {
60    ?indicatie a onz-zorg:WlzIndicatie .
61    BIND(1 AS ?wlz) .
62  }
63  OPTIONAL {
64    ?indicatie a onz-zorg:ZvwIndicatie .
65    BIND(1 AS ?zvw) .
66  }
67  OPTIONAL {
68    ?indicatie a onz-zorg:WmoIndicatie .
69    BIND(1 AS ?wmo) .
70  }
71
72  {
73    ?locatie onz-g:partOf* ?vestiging_uri .
74    ?vestiging_uri a onz-org:Vestiging ;
75      onz-g:identifiedBy ?vest_nr ;
76      onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
77    ?vest_nr a onz-org:Vestigingsnummer ;
78      onz-g:hasDataValue ?vestiging .
79
80    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
81    ?pc_gebied onz-g:identifiedBy ?postcode ;
82      onz-g:partOf+ ?zk_regio .
83    ?zk_regio a onz-org:ZorgkantoorRegio .
84  } UNION {
85    ?locatie onz-g:partOf* ?vestiging_uri .
86    ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
87    BIND("Totaal organisatie" AS ?vestiging)
88  }
89
90  BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
91
92
93}
94GROUP BY ?Periode ?vestiging
95ORDER BY ?Periode ?vestiging
96