1.6. Wat is het aantal cliënten per financieringsstroom?

Concepten

• Forensische indicatiestelling
• Indicatiebesluit
• Mens
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• Wmo-indicatie
• Zorgkantoor regio
• Zvw-indicatie

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Actiz 1.6
2# Parameters: ?jaar, ?kwartaal
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9
10SELECT
11    (?vestiging AS ?Indeling)
12    (IF(?vestiging = "Totaal organisatie", "", SAMPLE(?zk_regio_code)) AS ?Zorgkantoor_regio_code)
13    (COUNT(DISTINCT IF(BOUND(?wlz), ?client, ?unbound)) AS ?Wlz)
14    (COUNT(DISTINCT IF(BOUND(?zvw), ?client, ?unbound)) AS ?Zvw)
15    (COUNT(DISTINCT IF(BOUND(?wmo), ?client, ?unbound)) AS ?Wmo)
16    (COUNT(DISTINCT IF(!BOUND(?zvw) && !BOUND(?wlz) && !BOUND(?wmo), ?client, ?unbound)) AS ?Overig)
17WHERE {
18#    BIND(2024 AS ?jaar)
19#    BIND("Q1" AS ?kwartaal)
20    BIND(
21        IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
22            IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
23                IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
24                    IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
25                        ''))))
26        AS ?peildatum_eerder
27    )
28    BIND(?peildatum_eerder + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?peildatum_later)
29    BIND(IF(?vestiging = "Totaal organisatie", 1, 0) AS ?sortKey)
30
31    # --- Indicaties ---
32    {
33        ?indicatie a onz-zorg:IndicatieBesluit
34    } UNION {
35        ?indicatie a onz-zorg:ForensischeIndicatieStelling
36    }
37
38    ?indicatie
39        onz-g:isAbout ?client ;
40        onz-g:startDatum ?start_indicatie .
41    OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie . }
42
43    FILTER (
44        ?start_indicatie <= ?peildatum_later &&
45        (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?peildatum_eerder)
46    )
47
48    ?client a onz-g:Human .
49
50    OPTIONAL {
51        ?indicatie a onz-zorg:WlzIndicatie .
52        BIND(1 AS ?wlz) .
53    }
54    OPTIONAL {
55        ?indicatie a onz-zorg:ZvwIndicatie .
56        BIND(1 AS ?zvw) .
57    }
58    OPTIONAL {
59        ?indicatie a onz-zorg:WmoIndicatie .
60        BIND(1 AS ?wmo) .
61    }
62
63    # --- Locatie en regio ---
64    ?indicatie ^onz-g:definedBy/onz-g:hasPerdurantLocation ?locatie .
65
66    {
67        # Tak 1: echte vestiging + afleiding zorgkantoorregio
68        ?locatie onz-g:partOf* ?vestiging_uri .
69        ?vestiging_uri a onz-org:Vestiging ;
70            onz-g:identifiedBy ?vest_nr ;
71            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
72        ?vest_nr a onz-org:Vestigingsnummer ;
73            onz-g:hasDataValue ?vestiging .
74
75        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
76        ?pc_gebied onz-g:identifiedBy ?postcode ;
77            onz-g:partOf+ ?zk_regio .
78        ?zk_regio a onz-org:ZorgkantoorRegio .
79    } UNION {
80        # Tak 2: totaal organisatie, laat ?zk_regio ongebonden (leeg in output)
81        ?locatie onz-g:partOf* ?vestiging_uri .
82        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
83        BIND("Totaal organisatie" AS ?vestiging)
84    }
85
86    BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
87}
88GROUP BY ?vestiging ?sortKey
89ORDER BY ?sortKey ?vestiging
90