2.4. Wat is het percentage ingezette uren personeel in loondienst (PIL) en personeel niet in loondienst (PNIL)?

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• Inhuurovereenkomst
• Uitzendovereenkomst
• Werkovereenkomst afspraak

Relaties

• gedefinieerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ActiZ 2.4
2# Parameters: ?jaar, ?kwartaal
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT 
12    ("Organisatie" AS ?Organisatie)
13    (SUM(?uren * ?pil) AS ?Ingezette_uren_PIL)
14    (SUM(?uren * ?pnil) AS ?Ingezette_uren_PNIL)
15    (100*SUM(?uren * ?pnil)/SUM(?uren) AS ?percentage_ingezette_uren_PNIL)
16    (100*SUM(?uren * ?pil)/SUM(?uren) AS ?percentage_ingezette_uren_PIL)
17{
18    #BIND(2024 AS ?jaar)
19    #BIND("Q1" AS ?kwartaal)
20    
21    BIND(IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
22        IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
23        IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
24        IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
25        '')))) AS ?start_periode)
26    BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
27    
28    VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomst onz-pers:InhuurOvereenkomst onz-pers:UitzendOvereenkomst}
29    
30    ?overeenkomst 
31        a ?type_overeenkomst ; # personeel in loondienst (arbeidsovereenkomst) en personeel niet in loondienst (inhuur- en uitzendovereenkomst)
32        onz-pers:heeftOpdrachtnemer ?persoon ;
33        onz-g:hasPart ?overeenkomst_afspraak .
34    ?overeenkomst_afspraak
35        a onz-pers:WerkOvereenkomstAfspraak ;
36        onz-g:startDatum ?start_afspraak .
37    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
38    FILTER(?start_afspraak <= ?eind_periode && ((?eind_afspraak >= ?start_periode) || (!BOUND(?eind_afspraak))))
39    
40    ?inzet
41        a onz-pers:GewerktePeriode ;
42        onz-g:definedBy ?overeenkomst ;
43        onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
44        onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?uren .
45    
46    BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
47    FILTER(?start_inzet >= ?start_periode && ?start_inzet <= ?eind_periode)
48    FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
49    
50    BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomst, 1, 0) AS ?pil)
51    BIND(1 - ?pil AS ?pnil)
52}
53