Uitwisselprofiel ActiZ Belangenbehartiging

Over Uitwisselprofiel ActiZ Belangenbehartiging

Publicatiedatum:
18-12-2025
Inwerkingtreding:
01-02-2026
Bekijk bron...

2.5. Wat is de verhouding tussen het aantal personeelsleden met een zorgverlenersfunctie en het aantal cliënten?

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ActiZ 2.5
2# Parameters: ?jaar, ?kwartaal
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
12PREFIX time: <http://www.w3.org/2006/time#>
13
14SELECT 
15    (?vestiging AS ?Indeling)
16    (?zk_regio_code AS ?Zorgkantoorregiocode)
17    ?Aantal_ingezette_uren
18    ?Aantal_ligdagen
19    (IF(?Aantal_ingezette_uren != 0, ?Aantal_ligdagen / (?Aantal_ingezette_uren / 24) , "Ongedefinieerd") AS ?Aantal_cliënten_tov_1_medewerker)
20WHERE {
21    {
22        SELECT
23            ?vestiging
24            ?zorgkantoor_vestiging
25            ?zk_regio_code
26            (SUM(?gewerkte_uren) AS ?Aantal_ingezette_uren)
27        WHERE {
28            #BIND(2024 AS ?jaar)
29            #BIND("Q1" AS ?kwartaal)
30            BIND(IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
31                IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
32                IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
33                IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
34                '')))) AS ?start_periode)
35            BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
36            
37            ?overeenkomst 
38                a onz-pers:WerkOvereenkomst ;
39                onz-g:hasPart ?overeenkomst_afspraak .
40            ?overeenkomst_afspraak
41                a onz-pers:WerkOvereenkomstAfspraak ;
42                onz-g:isAbout / a onz-pers:ZorgverlenerFunctie ;
43                onz-g:isAbout ?locatie_afspraak ;
44                onz-g:startDatum ?start_afspraak .
45            OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak . }
46            ?locatie_afspraak a onz-g:StationaryArtifact .
47            
48            FILTER(?start_afspraak <= ?eind_periode && ((?eind_afspraak >= ?start_periode) || (!BOUND(?eind_afspraak))))
49            BIND(IF(?start_afspraak < ?start_periode, ?start_periode, ?start_afspraak) AS ?start_afspraak_corr)
50            BIND(IF(?eind_afspraak > ?eind_periode || !BOUND(?eind_afspraak), ?eind_periode, ?eind_afspraak) AS ?eind_afspraak_corr)
51            
52            ?inzet
53                a onz-pers:GewerktePeriode ;
54                onz-g:definedBy ?overeenkomst ;
55                onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
56                onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?gewerkte_uren .
57            OPTIONAL { ?inzet onz-g:hasPerdurantLocation ?locatie_inzet . }
58            BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
59            
60            FILTER(?start_inzet >= ?start_afspraak_corr && (?start_inzet <= ?eind_afspraak_corr || !BOUND(?eind_afspraak_corr)))
61            BIND(IF(BOUND(?locatie_inzet), ?locatie_inzet, ?locatie_afspraak) AS ?locatie)
62            
63            ?locatie a onz-g:StationaryArtifact .
64            ?locatie onz-g:partOf* ?vestiging_uri .
65            ?vestiging_uri a onz-org:Vestiging ;
66                onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
67            BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
68            ?pc_gebied 
69                onz-g:identifiedBy ?postcode ;
70                onz-g:partOf+ ?zk_regio .
71            ?zk_regio a onz-org:ZorgkantoorRegio .
72            ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
73            {
74                ?vestiging_uri onz-g:identifiedBy ?vest_nr .
75                ?vest_nr
76                    a onz-org:Vestigingsnummer ;
77                    onz-g:hasDataValue ?vestiging .
78                BIND(STRAFTER(STR(?zk_regio), "onz-org/") AS ?zk_regio_code)
79            } UNION {
80                # Includeer ook de organisatie als geheel en label deze als vestiging
81                ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
82                BIND("Totaal organisatie" AS ?vestiging)
83                BIND("n.v.t." AS ?zk_vestiging)
84                BIND("n.v.t." AS ?zk_regio_code)
85            }
86            BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
87         
88        } GROUP BY ?vestiging ?zorgkantoor_vestiging ?zk_regio_code
89    }
90    
91    {
92        SELECT
93            ?vestiging
94            ?zorgkantoor_vestiging
95            ?zk_regio_code
96            (SUM(?ligdagen) AS ?Aantal_ligdagen)
97            #(COUNT(distinct ?client) AS ?Aantal_ligdagen)
98        {
99            #BIND(2024 AS ?jaar)
100            #BIND("Q1" AS ?kwartaal)
101            BIND(IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
102                IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
103                IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
104                IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
105                '')))) AS ?start_periode)
106            BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
107            
108            VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
109             
110            ?indicatie 
111                a onz-zorg:WlzIndicatie ;
112                onz-g:startDatum ?start_indicatie ;
113                onz-g:hasPart ?zorgprofiel ;
114                onz-g:hasPart onz-zorg:instelling ;  # Verblijf leveringsvorm
115                onz-g:isAbout ?client .
116            OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie . }
117            ?client a onz-g:Human .
118            
119            FILTER(?start_indicatie <= ?eind_periode && ((?eind_indicatie >= ?start_periode) || (!BOUND(?eind_indicatie))))
120            BIND(IF(?start_indicatie < ?start_periode, ?start_periode, ?start_indicatie) AS ?start_indicatie_corr)
121            BIND(IF(?eind_indicatie > ?eind_periode || !BOUND(?eind_indicatie), ?eind_periode, ?eind_indicatie) AS ?eind_indicatie_corr)
122            
123            ?zorgproces
124                a onz-zorg:NursingProcess ;
125                onz-g:definedBy ?indicatie ;
126                onz-g:hasPerdurantLocation ?locatie ;
127                onz-g:startDatum ?start_zorgproces .
128            OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces . }
129            FILTER(?start_zorgproces <= ?eind_periode && ((?eind_zorgproces >= ?start_periode) || (!BOUND(?eind_zorgproces)))) 
130            BIND(IF(?start_zorgproces < ?start_indicatie_corr, ?start_indicatie_corr, ?start_zorgproces) AS ?start_zorgproces_corr)
131            BIND(IF(?eind_zorgproces > ?eind_indicatie_corr || !BOUND(?eind_indicatie), ?eind_indicatie_corr, ?eind_indicatie) AS ?eind_zorgproces_corr)
132            
133            ?start_zorgproces_corr ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?start_dag_reken .
134            ?eind_zorgproces_corr ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?eind_dag_reken .
135            BIND(?eind_dag_reken - ?start_dag_reken + 1 AS ?ligdagen)
136            
137            ?locatie onz-g:partOf* ?vestiging_uri .
138            ?vestiging_uri a onz-org:Vestiging ;
139                            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
140            BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
141            ?pc_gebied 
142                onz-g:identifiedBy ?postcode ;
143                onz-g:partOf+ ?zk_regio .
144            ?zk_regio a onz-org:ZorgkantoorRegio .
145            ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
146            {
147                ?vestiging_uri onz-g:identifiedBy ?vest_nr .
148                ?vest_nr 
149                    a onz-org:Vestigingsnummer ;
150                    onz-g:hasDataValue ?vestiging .
151                BIND(STRAFTER(STR(?zk_regio), "onz-org/") AS ?zk_regio_code)
152            } UNION {
153                # Includeer ook de organisatie als geheel en label deze als vestiging
154                ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
155                BIND("Totaal organisatie" AS ?vestiging)
156                BIND("n.v.t." AS ?zk_vestiging)
157                BIND("n.v.t." AS ?zk_regio_code)
158            }
159            BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
160        } GROUP BY ?vestiging ?zorgkantoor_vestiging ?zk_regio_code
161    }
162}
163ORDER BY ?Indeling
164
Terug naar: 2.4. Wat is het percentage ingezette uren personeel in loondienst (PIL) en personeel niet in loondienst (PNIL)?