2.1. Wat is het percentage instroom van zorggerelateerd personeel in loondienst?

Concepten

• Arbeidsovereenkomst
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ActiZ 2.1
2# Parameters: ?jaar, ?kwartaal
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8
9SELECT
10    ("Organisatie" as ?Organisatie)
11    (SUM(?noemer_waarde) AS ?Aantal_PIL_met_zorgfunctie)
12    (SUM(?teller_waarde) AS ?Aantal_ingestroomde_PIL_met_zorgfunctie)
13    (IF(?Aantal_PIL_met_zorgfunctie = 0, "Ongedefinieerd", 100*(?Aantal_ingestroomde_PIL_met_zorgfunctie/?Aantal_PIL_met_zorgfunctie)) AS ?Percentage_Instroom)
14{
15    SELECT
16        ?werknemer
17        (IF(MAX(?op_peildatum_eerder) = 1, 1, 0) AS ?noemer_waarde)
18        (IF(MAX(?op_peildatum_eerder) = 0 && MAX(?op_peildatum_later) = 1, 1, 0) AS ?teller_waarde)
19    {
20#       BIND(2024 AS ?jaar)
21#    	BIND("Q1" AS ?kwartaal)
22        BIND(IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
23            IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
24            IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
25            IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
26            '')))) AS ?peildatum_eerder)
27    	BIND(?peildatum_eerder + "P3M"^^xsd:duration AS ?peildatum_later)
28
29        ?overeenkomst
30            a onz-pers:ArbeidsOvereenkomst ;
31            onz-pers:heeftOpdrachtnemer ?werknemer ;
32            onz-g:hasPart ?overeenkomst_afspraak .
33
34        ?overeenkomst_afspraak
35            a onz-pers:WerkOvereenkomstAfspraak ;
36            onz-g:isAbout ?functie ;
37            onz-g:startDatum ?start_afspraak .
38
39        ?functie
40            a onz-pers:ZorgverlenerFunctie .
41        
42        OPTIONAL {
43            ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
44        }
45
46      BIND(IF(?start_afspraak <= ?peildatum_later && (!BOUND(?eind_afspraak) || ?eind_afspraak >= ?peildatum_later), 1, 0) AS ?op_peildatum_later)
47      BIND(IF(?start_afspraak <= ?peildatum_eerder && (!BOUND(?eind_afspraak) || ?eind_afspraak >= ?peildatum_eerder), 1, 0) AS ?op_peildatum_eerder)
48
49    }
50    GROUP BY ?werknemer
51}