12.1.5 Verzuimfrequentie (excl. zwangerschapsverlof) Q1 2024

Concepten

• Arbeidsovereenkomst
• Bedrijf
• Inhuurovereenkomst
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Ziekteperiode
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deelnemer
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 12.1
2# Parameters: ($kwartaal)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX onz-g: <http://purl.org/ozo/onz-g#>
10PREFIX onz-org: <http://purl.org/ozo/onz-org#>
11PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
12
13SELECT 
14    ?vestiging
15    (COUNT(?overeenkomst) AS ?aantal_arbeidsovereenkomsten)
16    (SUM(?meldingen) AS ?aantal_meldingen)
17    (SUM(?meldingen) / COUNT(?overeenkomst) AS ?verzuimfrequentie)
18{
19    {
20        SELECT 
21            DISTINCT ?overeenkomst 
22            ?vestiging 
23            (SUM(?melding) AS ?meldingen)
24        {
25            BIND('Q1' AS ?kwartaal)
26            BIND(IF(?kwartaal = 'Q1', '2024-01-01'^^xsd:date, 
27                IF(?kwartaal = 'Q2', '2024-04-01'^^xsd:date,
28                IF(?kwartaal = 'Q3', '2024-07-01'^^xsd:date,
29                IF(?kwartaal = 'Q4', '2024-10-01'^^xsd:date, 
30                '')))) AS ?start_periode)
31            BIND(?start_periode + "P3M"^^xsd:duration - "P1D"^^xsd:duration AS ?eind_periode)
32            # Keuze in-/exclusief zwangerschapsverlog
33            VALUES ?type_verzuim
34            { 
35                onz-pers:ZiektePeriode
36                #onz-pers:ZwangerschapsVerlof
37            }
38
39            # Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
40            VALUES ?personeels_overeenkomst 
41            { 
42                onz-pers:ArbeidsOvereenkomst
43                onz-pers:UitzendOvereenkomst
44                onz-pers:InhuurOvereenkomst
45            }
46            ?functie
47                a onz-pers:ZorgverlenerFunctie ;
48                onz-g:startDatum ?start_functie .
49            OPTIONAL {?functie a onz-pers:ZorgverlenerFunctie ;
50                     onz-g:eindDatum ?eind_functie }
51            ?overeenkomst 
52                a ?personeels_overeenkomst ; #Alleen personeel
53                onz-pers:heeftOpdrachtnemer ?werknemer ;
54                onz-g:isAbout ?locatie ;
55                onz-g:isAbout ?functie .
56            
57            FILTER (?start_functie <= ?eind_periode && (!BOUND(?eind_functie) || ?eind_functie >= ?start_periode))
58
59            OPTIONAL {
60                ?werknemer
61                    ^onz-g:hasParticipant ?ziekteperiode .
62                ?ziekteperiode
63                    a ?type_verzuim ;
64                    onz-g:startDatum ?start_ziekte .
65                # Ziektemelding moet vallen binnen de meetperiode EN per overeenkomst binnen de geldigheid van die overeenkomst
66                FILTER (?start_ziekte >= ?start_periode && ?start_ziekte <= ?eind_periode)
67                FILTER (?start_ziekte >= ?start_functie && (?start_ziekte <= ?eind_functie || !BOUND(?eind_functie)))
68            }
69            BIND(IF(BOUND(?ziekteperiode), 1, 0) AS ?melding)
70            #Bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
71            {
72                ?locatie onz-g:partOf* ?vestiging_uri .
73                ?vestiging_uri 
74                    a onz-org:Vestiging ;
75                    onz-g:identifiedBy ?vest_nr.
76                ?vest_nr
77                    a onz-org:Vestigingsnummer ;
78                    onz-g:hasDataValue ?vestiging .
79            } UNION {
80                #Includeer ook de organisatie als geheel en label deze als vestiging
81                ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
82                ?organisatie_uri 
83                    a onz-g:Business ;
84                    rdfs:label ?Organisatie .
85                BIND(CONCAT('Totaal ',?Organisatie) AS ?vestiging)
86            }
87        }
88        GROUP BY ?overeenkomst ?vestiging
89    }
90}
91GROUP BY ?vestiging