8.2.2 Percentage kosten personeel niet in loondienst (PNIL) Q2 2023

Concepten

• Financiële entiteit
• Grootboekpost
• Kostenplaats
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde

Eigenschappen

• heeft datawaarde
• heeft datum

Instanties

• Aandeel werkgever premies sociale verzekeringen
• Aandeel werknemer premies sociale verzekeringen
• Berekende sociale kosten vakantiebijslag
• Korting / vrijlating basispremie WAO / werkgeverdeel Awf
• Leerling-verpleegkundig, -opvoedkundig en -verzorgend personeel
• Overgeboekte sociale kosten
• Pensioenkosten
• Personeel algemene en administratieve functies
• Personeel hotelfuncties
• Personeel patiënt- c.q. bewonergebonden functies
• Personeel terrein- en gebouwgebonden functies
• Vergoedingen voor niet in loondienst verrichte arbeid
• Ziektekostenverzekering

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 8.2.2
2# Parameters: -
3# Ontologie: versie 2.1.1
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT 
13    ?vestiging
14    (SUM(?bedrag_pil)AS ?totaal_pil_kosten) 
15    (SUM(?bedrag_pnil)AS ?totaal_pnil_kosten) 
16    ((SUM(?bedrag_pnil)/((SUM(?bedrag_pil)+SUM(?bedrag_pnil)))*100) AS ?percentage_kosten_pnil)
17{
18    {
19        SELECT ?grootboek_post ?bedrag_pil ?bedrag_pnil ?vest
20        {
21            {
22                SELECT DISTINCT ?grootboek_post ?bedrag_pil ?bedrag_pnil
23                {
24                    BIND ('2023-04-01'^^xsd:date AS ?start_periode)      
25                    BIND ('2023-06-30'^^xsd:date AS ?eind_periode)
26                    {
27                        VALUES ?rubriek_pnil { 
28                            onz-fin:WBedOvpUik
29                            onz-fin:WBedOvpUit
30                            onz-fin:WBedOvpMaf
31                            onz-fin:WBedOvpZzp
32                            onz-fin:WBedOvpPay
33                            onz-fin:WBedOvpOip
34
35                            onz-fin:PM418000
36                        }
37                        # selecteer de grootboek posten met kostenplaats
38                        ?grootboek_post a onz-fin:Grootboekpost ;
39                            onz-g:partOf ?rubriek_pnil ;
40                            onz-g:isAbout ?kosten_pnil ;
41                            onz-g:hasDate ?datum .
42                        ?kosten_pnil
43                            a onz-g:FinancialEntity ;
44                            onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?bedrag_pnil .
45                        BIND(0 AS ?bedrag_pil)
46                    } UNION {
47                        VALUES ?rubriek_pil { 
48                            onz-fin:WPerLes
49                            onz-fin:WPerSol
50                            
51                            onz-fin:PM411000
52                            onz-fin:PM412000
53                            onz-fin:PM413000
54                            onz-fin:PM414000
55                            onz-fin:PM415000
56                            onz-fin:PM422100
57                            onz-fin:PM422300
58                            onz-fin:PM422400
59                            onz-fin:PM422410
60                            onz-fin:PM422500
61                            onz-fin:PM422600
62                            onz-fin:PM422900
63                        }
64                        # selecteer de grootboek posten met kostenplaats
65                        ?grootboek_post a onz-fin:Grootboekpost ;
66                            onz-g:partOf ?rubriek_pil ;
67                            onz-g:isAbout ?kosten_pil ;
68                            onz-g:hasDate ?datum .
69                        ?kosten_pil
70                            a onz-g:FinancialEntity ;
71                            onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?bedrag_pil .
72                        BIND(0 AS ?bedrag_pnil)
73                    }
74                    # filter binnen periode
75                    FILTER (?datum >= ?start_periode && ?datum <= ?eind_periode)
76                }
77            }   
78            OPTIONAL 
79            {
80                ?grootboek_post onz-g:isAbout ?kosten_plaats .
81                ?kosten_plaats a onz-fin:Kostenplaats;
82                                onz-g:isAbout ?vestiging_uri .
83                ?vestiging_uri 
84                    a onz-org:Vestiging ;
85                    onz-g:identifiedBy ?vest_nr.
86                ?vest_nr a onz-org:Vestigingsnummer ;
87                    onz-g:hasDataValue ?vestiging_label .
88            }
89        BIND(IF(!BOUND(?vestiging_label),"Onbekend",?vestiging_label) AS ?vest)
90        }
91    }
92    {
93        BIND(?vest AS ?temp)
94    } UNION {
95        BIND("Totaal" AS ?temp)
96    }
97    BIND(IF(!BOUND(?temp),?vest,?temp) AS ?vestiging)
98}
99GROUP BY ?vestiging
100ORDER BY ?vestiging```