13.2.0 Percentage uitstroom personeel in loondienst

Concepten

• Arbeidsovereenkomst
• Inhuurovereenkomst
• Uitzendovereenkomst
• Zorgverlener (functie)

Relaties

• gaat over
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 13.2
2# Parameters: $(peildatum)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX onz-g: <http://purl.org/ozo/onz-g#>
10PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
11
12SELECT 
13	(COUNT(?werknemer) AS ?noemer)
14    (SUM(?uitstroom) AS ?teller)
15    (xsd:integer(ROUND(100*(SUM(?uitstroom)/COUNT(?werknemer)))) AS ?indicator)
16WHERE
17{
18    {
19        SELECT 
20            ?werknemer
21            (MIN(?weg) AS ?uitstroom)
22        {
23            BIND($(peildatum) AS ?peildatum)
24            BIND((?peildatum - "P1Y"^^xsd:duration) AS ?peildatum_eerder)
25
26            # Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
27            VALUES ?personeels_overeenkomst 
28            { 
29                onz-pers:ArbeidsOvereenkomst
30                onz-pers:UitzendOvereenkomst
31                onz-pers:InhuurOvereenkomst
32            }
33            ?functie 
34                a onz-pers:ZorgverlenerFunctie ;
35                onz-g:startDatum ?start_functie .
36            OPTIONAL {?functie a onz-pers:ZorgverlenerFunctie ;
37        		onz-g:eindDatum ?eind_functie}
38            FILTER (?start_functie <= ?peildatum && ((?eind_functie >= ?peildatum)||(!BOUND(?eind_functie))))
39            ?overeenkomst 
40                a ?personeels_overeenkomst ; #Alleen personeel
41                onz-pers:heeftOpdrachtnemer ?werknemer ;
42                onz-g:isAbout ?functie .
43            
44            # Teller is populatie die op peildatum is uitgestroomd
45            # Kijk of er op peildatum nog steeds een arbeidsovereenkomst was die aan de voorwaarden voldoet
46            OPTIONAL {
47                ?functie_oud
48                    a onz-pers:ZorgverlenerFunctie ;
49                    onz-g:startDatum ?start_functie_oud .
50                OPTIONAL {?functie_oud a onz-pers:ZorgverlenerFunctie ;
51                    onz-g:eindDatum ?eind_functie_oud}
52                FILTER (?start_functie_oud <= ?peildatum_eerder && (?eind_functie_oud >= ?peildatum_eerder || !BOUND(?eind_functie_oud)))
53                     
54                ?overeenkomst_oud
55                    a ?personeels_overeenkomst ; #Alleen personeel
56                    onz-pers:heeftOpdrachtnemer ?werknemer ;
57                    onz-g:isAbout ?functie_oud .
58            }
59            BIND(IF(BOUND(?functie_oud), 0, 1) AS ?weg)
60        }   
61        GROUP BY ?werknemer
62    }
63}