1.2. Casuïstiekbespreking decubitus

Concepten

• Casuïstiekbespreking decubitus
• Decubituswond
• Verpleegproces
• Vestiging

Relaties

• deel van
• gedefinieerd door
• heeft deel
• heeft deelnemer
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft onderwerp van bijeenkomst
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft tijdwaarde
• startdatum

Instanties

• Decubitus categorie 2
• Decubitus categorie 3
• Decubitus categorie 4
• VV Beschermd verblijf met intensieve palliatief-terminale zorg
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
3PREFIX onz-org: <http://purl.org/ozo/onz-org#>
4PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
7
8SELECT 
9    (SUM(?count_teller) AS ?teller)
10    (COUNT(?vestiging) AS ?noemer)
11    (ROUND(100 * SUM(?count_teller) / COUNT(?vestiging)) AS ?indicator)
12{
13    {
14
15        SELECT DISTINCT ?vestiging (MAX(?inclusie_teller) AS ?count_teller)
16        {
17            BIND("2023-01-01"^^xsd:date AS ?start_periode)    
18            BIND("2023-12-31"^^xsd:date AS ?eind_periode)
19
20            VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
21            VALUES ?categorie_inclusie { onz-zorg:decubitus_categorie_2 onz-zorg:decubitus_categorie_3 onz-zorg:decubitus_categorie_4 }
22            
23            #selecteer de zorgprocessen die voldoen aan de inclusiecriteria
24            ?zorgproces
25                a onz-zorg:NursingProcess ;
26                onz-g:hasPerdurantLocation ?locatie ;
27                onz-g:hasParticipant ?client ;
28                onz-g:definedBy/onz-g:hasPart ?zorgprofiel ;
29                onz-g:startDatum ?start_proces .
30                OPTIONAL {?zorgproces onz-g:eindDatum ?eind_proces}
31            ?locatie 
32                onz-g:partOf* ?vestiging .
33            ?vestiging a onz-org:Vestiging .
34
35            #selecteer decubituswonden van graad 2 en hoger
36            ?client 
37                onz-g:hasQuality ?wond .
38            ?wond 
39                a onz-zorg:DecubitusWond ;
40                onz-g:hasQuality ?ernst .
41            ?ernst 
42                onz-g:hasTime ?datum ;
43                onz-g:hasQualityValue ?categorie_inclusie .
44
45            #wond in de juiste periode en bij juiste proces
46            FILTER (?datum <= ?eind_periode && ?datum >= ?start_periode)
47            FILTER (?datum >= ?start_proces && (?datum <= ?eind_proces || !BOUND(?eind_proces)))
48            
49            OPTIONAL {
50                ?bespreking 
51                    a onz-zorg:CasuistiekBesprekingDecubitus ;
52                    onz-g:hasMeetingTopic ?wond ;
53                    onz-g:hasTime ?datum_bespreking ;
54                #bespreking in de juiste periode
55                FILTER (?datum_bespreking <= ?eind_periode && ?datum_bespreking >= ?start_periode)
56            }
57            BIND(IF(BOUND(?bespreking), 1, 0) AS ?inclusie_teller)
58        }
59        GROUP BY ?vestiging
60    }
61}```