Uitwisselprofiel Zorginstituut Openbaarmaking kwaliteitsindicatoren verpleeghuiszorg

Versie:

Publicatiedatum:21-12-2023

Inwerkingtreding:21-12-2023




Bekijk bron...

2. Gezamenlijke afspraken over behandeling rond het levenseinde

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd

...

Kopieer naar klembord

1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
3PREFIX onz-org: <http://purl.org/ozo/onz-org#>
4PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
5PREFIX time: <http://www.w3.org/2006/time#>
6PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8
9SELECT
10    ?vestiging
11    ?teller
12    ?noemer
13    ?indicator
14{
15    {
16        SELECT
17            ?vestiging
18            (SUM(?inclusie_teller) AS ?teller_temp)
19            (COUNT(?client) AS ?noemer_temp)
20            (ROUND(100 * SUM(?inclusie_teller) / COUNT(?client)) AS ?indicator_temp)
21        {
22            {
23                SELECT 
24                    ?client
25                    (MAX(?start_proces) AS ?start_laatste_proces) #zodat meest recente vestiging gevonden kan worden
26                    (MAX(?tlr) AS ?inclusie_teller) #MAX zodat een client maar 1x mee kan tellen
27                {
28                    BIND("2023-03-01"^^xsd:date as ?peildatum)
29
30                    VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
31                    
32                    #selecteer de zorgprocessen die voldoen aan de inclusiecriteria
33                    ?zorgproces
34                        a onz-zorg:NursingProcess ;
35                        onz-g:hasParticipant ?client ;
36                        onz-g:definedBy/onz-g:hasPart ?zorgprofiel ;
37                        onz-g:startDatum ?start_proces .
38                        OPTIONAL {?zorgproces onz-g:eindDatum ?eind_proces}
39                    
40                    FILTER (?start_proces <= ?peildatum && (!BOUND(?eind_proces) || ?eind_proces >= ?peildatum))
41
42                    #selecteer eventuele beleidsafspraken rondom het levenseinde
43                    OPTIONAL {
44                        ?beleidsafspraak 
45                            a onz-zorg:AfspraakLevenseinde ;
46                            onz-g:isAbout ?client ;
47                            onz-g:startDatum ?datum .
48                        FILTER (?datum <= ?peildatum)
49                    }
50                    BIND(IF(BOUND(?beleidsafspraak),1,0) AS ?tlr)
51                } 
52                GROUP BY ?client
53            }
54            #Vind de laatste vestiging binnen de verslagperiode en koppel deze aan de client
55            ?laatsteproces 
56                onz-g:hasParticipant ?client ;
57                onz-g:startDatum ?start_laatste_proces ;
58                onz-g:hasPerdurantLocation ?locatie .
59            ?locatie 
60                onz-g:partOf* ?vestiging_uri .
61            ?vestiging_uri 
62                a onz-org:Vestiging ;
63                onz-g:identifiedBy ?vest_nr .
64            ?vest_nr
65                a onz-org:Vestigingsnummer ;
66                onz-g:hasDataValue ?vestiging .
67        }
68        GROUP BY ?vestiging
69    }
70    #Corrigeer voor waarnemingen kleiner dan 10
71    #Houd rekening met een teller die mogelijk groter is dan de noemer
72    BIND (IF(?teller_temp < 10, "Waarneming kleiner dan 10", ?teller_temp) AS ?teller)
73    BIND (IF(?noemer_temp < 10, "Waarneming kleiner dan 10", ?noemer_temp) AS ?noemer)
74    BIND (IF(?teller_temp < 10, "Waarneming kleiner dan 10", ?indicator_temp) AS ?indicator)
75}

Heb je feedback?

Loopt u tegen een issue of vraag aan bij het KIK-V product? Neem dan contact met ons op!