3.2. Medicatiereview

Concepten

• Medicatiereview
• Verpleegproces
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft deelnemer
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• heeft tijdwaarde
• startdatum

Instanties

• VV Beschermd verblijf met intensieve palliatief-terminale zorg
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
3PREFIX onz-org: <http://purl.org/ozo/onz-org#>
4PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
7
8SELECT
9    ?vestiging
10    (SUM(?tlr) AS ?teller)
11    (COUNT(?client) AS ?noemer)
12    (ROUND(100 * SUM(?tlr) / COUNT(?client)) AS ?indicator)
13{
14    {
15        SELECT 
16            ?client 
17            (MAX(?start_proces) AS ?start_laatste_locatie)
18            (MAX(?inclusie_teller) AS ?tlr)
19        {
20            {
21                SELECT
22                    ?client
23                    ?start_periode
24                    ?eind_periode
25                {
26                    {
27                        SELECT 
28                            ?client
29                            ?start_periode
30                            ?eind_periode
31                            (MIN(?start_proces) AS ?start_inclusie)
32                            (MAX(?eind_proces_corr) AS ?eind_inclusie)
33                        { 
34                            BIND("2023-01-01"^^xsd:date AS ?start_periode)    
35                            BIND("2023-10-31"^^xsd:date AS ?eind_periode)
36
37                            VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
38                            
39                            #selecteer de clienten die op eind van de periode minimaal 6 maanden in dienst zijn
40                            ?zorgproces
41                                a onz-zorg:NursingProcess ;
42                                onz-g:hasParticipant ?client ;
43                                onz-g:definedBy/onz-g:hasPart ?zorgprofiel ;
44                                onz-g:startDatum ?start_proces .
45                                OPTIONAL {?zorgproces onz-g:eindDatum ?eind_proces}
46                                BIND(IF(!BOUND(?eind_proces) || ?eind_proces > ?eind_periode, ?eind_periode, ?eind_proces) AS ?eind_proces_corr)
47                        }
48                        GROUP BY ?client ?start_periode ?eind_periode
49                    }
50                    # Includeer indien meer dan 6 maanden zorg
51                    FILTER ((?eind_inclusie - ?start_inclusie) >= "P182D"^^xsd:duration)
52                }    
53            }
54            VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
55            ?zorgproces
56                a onz-zorg:NursingProcess ;
57                onz-g:hasParticipant ?client ;
58                onz-g:definedBy/onz-g:hasPart ?zorgprofiel ;
59                onz-g:startDatum ?start_proces .
60                OPTIONAL {?zorgproces onz-g:eindDatum ?eind_proces}
61                FILTER (?start_proces <= ?eind_periode && (!BOUND(?eind_proces) || ?eind_proces >= ?start_periode))
62            OPTIONAL {
63                ?medicatiereview 
64                    a onz-zorg:MedicatieReview ;
65                    onz-g:hasTime ?datum_review ;
66                    onz-g:isAbout ?client .
67                FILTER (?datum_review >= ?start_periode && ?datum_review <= ?eind_periode)
68            }
69            BIND(IF(BOUND(?medicatiereview), 1, 0) AS ?inclusie_teller)
70        }   
71        GROUP BY ?client
72    }
73    # Rapporteer bij de vestiging van het meest recente (in de gevraagde periode) zorgproces van de geincludeerde clienten
74    ?laatsteproces 
75        onz-g:hasParticipant ?client ;
76        onz-g:startDatum ?start_laatste_locatie ;
77        onz-g:hasPerdurantLocation ?locatie .
78    ?locatie 
79        onz-g:partOf* ?vestiging_uri .
80    ?vestiging_uri 
81        a onz-org:Vestiging ;
82        onz-g:identifiedBy ?vest_nr .
83    ?vest_nr
84        a onz-org:Vestigingsnummer ;
85        onz-g:hasDataValue ?vestiging .
86}
87GROUP BY ?vestiging