Uitwisselprofiel Zorginstituut Openbaarmaking kwaliteitsindicatoren verpleeghuiszorg

Versie:

Publicatiedatum:21-12-2023

Inwerkingtreding:21-12-2023




Bekijk bron...

2.4.2. Percentage uitstroom

Concepten

Relaties

Eigenschappen

SPARQL query

Code gekopieerd

...

Kopieer naar klembord

1# Indicator: ODB Personele samenstelling 2.4.2
2# Parameters: -
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8
9SELECT 
10	(SUM(coalesce(?uitstroom, 0)) AS ?teller)
11	((SUM(?count_start) + SUM(?count_eind))/2 AS ?noemer) 
12    (ROUND( 100 * (SUM(coalesce(?uitstroom, 0))/((SUM(?count_start) + SUM(?count_eind))/2))) AS ?indicator)
13WHERE
14{
15    {
16        SELECT
17            ?persoon 
18            (MAX(?geldig_verleden) AS ?count_start)
19            (MAX(?geldig_eind) AS ?count_eind)
20        WHERE 
21        { 
22            BIND ("2023-12-31"^^xsd:date AS ?peildatum)
23            BIND (?peildatum - "P1Y"^^xsd:duration AS ?verleden)
24        
25            # selecteer werkovereenkomsten waarbij werknemer een zorgverlenerfunctie heeft
26            ?functie 
27                a onz-pers:ZorgverlenerFunctie ;
28                onz-g:startDatum ?start_functie .
29            OPTIONAL {?functie a onz-pers:ZorgverlenerFunctie ;
30                onz-g:eindDatum ?eind_functie}
31            ?overeenkomst 
32                onz-g:isAbout ?functie ;
33                a onz-pers:ArbeidsOvereenkomst ;
34                onz-pers:heeftOpdrachtnemer ?persoon .
35
36            BIND(IF(?start_functie <= ?peildatum && (?eind_functie >= ?peildatum || !BOUND(?eind_functie)), 1, 0) AS ?geldig_eind)
37            BIND(IF(?start_functie <= ?verleden && (?eind_functie >= ?verleden || !BOUND(?eind_functie)), 1, 0) AS ?geldig_verleden)
38        
39        } GROUP BY ?persoon
40    } 
41BIND(IF(?count_start=1 && ?count_eind=0, 1, 0) AS ?uitstroom)
42}

Heb je feedback?

Loopt u tegen een issue of vraag aan bij het KIK-V product? Neem dan contact met ons op!