Uitwisselprofiel Zorginstituut Openbaarmaking kwaliteitsindicatoren verpleeghuiszorg

Versie:

Publicatiedatum:21-12-2023

Inwerkingtreding:21-12-2023




Bekijk bron...

2.1.4. Percentage inzet uitzendkrachten Personeel Niet in Loondienst (PNIL)

Concepten

Relaties

Eigenschappen

SPARQL query

Code gekopieerd

...

Kopieer naar klembord

1# Indicator: ODB Personele samenstelling 2.1.4
2# Parameters: -
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8
9SELECT
10	(SUM(?pnil_uren)/1692 AS ?teller)
11	(SUM(?uren)/1692 AS ?noemer) 
12	(100 * ?teller / ?noemer AS ?indicator)
13{
14    SELECT DISTINCT 
15		?gewerkte_periode 
16		?uren 
17		?pnil_uren
18    {
19        BIND ("2023-01-01"^^xsd:date AS ?start_periode)
20        BIND ("2023-12-31"^^xsd:date AS ?eind_periode)  
21
22        # selecteer zorgverlenerfuncties die geldig zijn binnen de periode
23        ?functie 
24            a onz-pers:ZorgverlenerFunctie ;
25            onz-g:startDatum ?start_functie .
26        OPTIONAL {
27            ?functie onz-g:eindDatum ?eind_functie
28        }
29        FILTER (?start_functie <= ?eind_periode && (?eind_functie >= ?eind_periode || !BOUND(?eind_functie)))
30        
31        VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomst onz-pers:InhuurOvereenkomst onz-pers:UitzendOvereenkomst}
32        # selecteer de arbeidsovereenkomst die hoort bij de functie
33        ?overeenkomst
34            a ?type_overeenkomst ;
35            onz-g:isAbout ?functie ;
36            onz-g:isAbout ?gewerkte_periode .
37
38        # selecteer aantal gewerkte uren binnen periode die gekoppeld zijn aan werkovereenkomst 
39        ?gewerkte_periode 
40            a onz-pers:GewerktePeriode ;
41            onz-g:hasBeginTimeStamp ?start_gewerktDT ;
42            onz-g:hasEndTimeStamp ?eind_gewerktDT ;
43            onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?uren .
44        BIND(STRDT(SUBSTR(STR(?start_gewerktDT),1,10), xsd:date) AS ?start_gewerkt)
45        BIND(STRDT(SUBSTR(STR(?eind_gewerktDT),1,10), xsd:date) AS ?eind_gewerkt)
46        # selecteer gewerkte tijd in de gevraagde periode
47        FILTER(?start_gewerkt >= ?start_periode && ?eind_gewerkt <= ?eind_periode)
48
49        # ken PNIL uren toe aan inhuur- en uitzendovereenkomsten
50        BIND(IF(?type_overeenkomst = onz-pers:InhuurOvereenkomst || ?type_overeenkomst = onz-pers:UitzendOvereenkomst, ?uren, 0) AS ?pnil_uren)
51    }
52}```

Heb je feedback?

Loopt u tegen een issue of vraag aan bij het KIK-V product? Neem dan contact met ons op!