Uitwisselprofiel Zorgkantoren Inkoopondersteuning en beleidsontwikkeling

Versie:

Publicatiedatum:29-02-2024

Inwerkingtreding:29-02-2024




Bekijk bron...

16.1. Aantal cliënten met het syndroom van Korsakov - peildatum 1-4-2023

Concepten

Relaties

Eigenschappen

SPARQL query

Code gekopieerd

...

Kopieer naar klembord

1# Indicator: Zorgkantoren 16.1
2# Parameters: -
3# Ontologie: versie 2.2.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
12SELECT ?vestiging (COUNT(DISTINCT ?client) AS ?aantal_clienten)
13{
14    BIND("2023-04-01"^^xsd:date AS ?peildatum)
15    VALUES ?prestatiecode { onz-fin:Vektis_EX001 }
16    
17    ?declaratie
18        a onz-fin:CareInvoice ;
19        onz-g:hasPart ?prestatiecode ;
20        onz-g:goedgekeurd "true"^^xsd:boolean ;
21        onz-g:isAbout ?zorgproces .
22    
23    ?zorgproces
24        a onz-zorg:NursingProcess ;
25        onz-g:hasParticipant ?client ;
26        onz-g:startDatum ?start_zorgproces ;
27        onz-g:hasPerdurantLocation ?locatie .
28    OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces .}
29    FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum) || (!BOUND(?eind_zorgproces))) )
30     
31     # selecteer vestiging van zorgproces
32     {
33         ?locatie onz-g:partOf* ?vestiging_uri .
34         ?vestiging_uri 
35             a onz-org:Vestiging ;
36             onz-g:identifiedBy ?vest_nr.
37         ?vest_nr 
38             a onz-org:Vestigingsnummer ;
39             onz-g:hasDataValue ?vestiging .
40     } UNION {
41         # includeer ook de organisatie als geheel en label deze als vestiging
42         ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
43         ?organisatie_uri 
44             a onz-g:Business ;
45             rdfs:label ?organisatie .
46         BIND(CONCAT('Totaal ',?organisatie) AS ?vestiging)
47     }
48
49}
50GROUP BY ?vestiging
51ORDER BY ?vestiging
52
53
54

Heb je feedback?

Loopt u tegen een issue of vraag aan bij het KIK-V product? Neem dan contact met ons op!