3.1.5 Percentage arbeidsovereenkomsten voor bepaalde tijd op 1-1-2024

Concepten

• Arbeidsovereenkomst
• Arbeidsovereenkomst bepaalde tijd
• Bedrijf
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 3.1
2# Parameters: ($peildatum)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12	?vestiging
13	(COUNT(DISTINCT ?personeel_bepaalde_tijd) AS ?aantal_bepaalde_tijd) 
14	(COUNT(DISTINCT ?personeel) AS ?totaal) 
15	(COUNT(DISTINCT ?personeel_bepaalde_tijd)/COUNT(DISTINCT ?personeel) *100 AS ?percentage_bepaalde_tijd)
16WHERE {     
17    # definieer peildatum
18    BIND("2024-01-01"^^xsd:date AS ?peildatum)
19    {
20        # selecteer personen met arbeidsovereenkomst bepaalde tijd
21        ?arbeidsovereenkomst a onz-pers:ArbeidsOvereenkomstBepaaldeTijd ;
22        	onz-g:startDatum ?start_overeenkomst ;
23        	onz-g:isAbout ?locatie ;
24        	onz-pers:heeftOpdrachtnemer ?personeel_bepaalde_tijd .
25        OPTIONAL {?arbeidsovereenkomst onz-g:eindDatum ?eind_overeenkomst}
26        
27        # bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
28        {
29            ?locatie onz-g:partOf* ?vestiging_uri .
30            ?vestiging_uri 
31                a onz-org:Vestiging ;
32                onz-g:identifiedBy ?vest_nr.
33            ?vest_nr a onz-org:Vestigingsnummer ;
34                onz-g:hasDataValue ?vestiging .
35        } UNION {
36            #Includeer ook de organisatie als geheel en label deze als vestiging
37            ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
38            ?organisatie_uri 
39                a onz-g:Business ;
40                rdfs:label ?organisatie .
41            BIND(CONCAT('Totaal ',?organisatie) AS ?vestiging)
42        }
43    } 
44    UNION
45    {
46        # selecteer personen met arbeidsovereenkomst
47        ?arbeidsovereenkomst a onz-pers:ArbeidsOvereenkomst ;
48        	onz-g:startDatum ?start_overeenkomst ;
49        	onz-g:isAbout ?locatie ;
50        	onz-pers:heeftOpdrachtnemer ?personeel .
51        OPTIONAL {?arbeidsovereenkomst onz-g:eindDatum ?eind_overeenkomst}
52        
53        # bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
54        {
55            ?locatie onz-g:partOf* ?vestiging_uri .
56            ?vestiging_uri 
57                a onz-org:Vestiging ;
58                onz-g:identifiedBy ?vest_nr.
59            ?vest_nr a onz-org:Vestigingsnummer ;
60                onz-g:hasDataValue ?vestiging .
61        } UNION {
62            #Includeer ook de organisatie als geheel en label deze als vestiging
63            ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
64            ?organisatie_uri 
65                a onz-g:Business ;
66                rdfs:label ?organisatie .
67            BIND(CONCAT('Totaal ',?organisatie) AS ?vestiging)
68        }
69    } 
70    # filter op peildatum
71    FILTER (?start_overeenkomst <= ?peildatum && (!BOUND(?eind_overeenkomst) || ?eind_overeenkomst >= ?peildatum))
72}
73GROUP BY ?vestiging
74ORDER BY ?vestiging
75