14.2.0 Aantal cliënten per leveringsvorm

Concepten

• Leveringsvorm
• Mens
• Verpleegproces
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• indicatie behandeling
• startdatum

Instanties

• VV Beschermd verblijf met intensieve palliatief-terminale zorg
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging
• Verblijf in een instelling

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
3PREFIX onz-org: <http://purl.org/ozo/onz-org#>
4PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
5PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
6PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
7
8SELECT
9    ?vestiging
10	?leveringsvorm
11    (COUNT (DISTINCT(?client)) AS ?indicator)
12WHERE
13{ 
14    BIND ($(peildatum) AS ?peildatum)
15    VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
16
17    #selecteer de zorgprocessen op de vestigingen die voldoen aan de inclusiecriteria
18    ?zorgproces
19        a onz-zorg:NursingProcess ;
20        onz-g:definedBy ?indicatie ;
21        onz-g:hasPerdurantLocation ?locatie ;
22        onz-g:startDatum ?start_zorgproces .
23    	OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
24    	FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces))))
25    ?locatie 
26        onz-g:partOf* ?vestiging_uri .
27    ?vestiging_uri 
28        a onz-org:Vestiging ;
29        onz-g:identifiedBy ?vest_nr.
30    ?vest_nr
31        a onz-org:Vestigingsnummer ;
32        onz-g:hasDataValue ?vestiging .
33    
34    #selecteer de bijbehordene indicatie, om unieke clienten te kunnen bepalen
35    ?indicatie 
36        onz-g:hasPart ?zorgprofiel ;
37        onz-g:hasPart ?lv ;
38        onz-g:isAbout ?client .
39  		OPTIONAL {?indicatie onz-zorg:heeftIndicatieBehandeling ?behandeling}
40        BIND(IF(BOUND(?behandeling), ?behandeling, "false"^^xsd:boolean) AS ?incl_behandeling)
41    ?client a onz-g:Human .
42  	?lv
43    	a onz-zorg:Leveringsvorm ;
44        rdfs:label ?leveringsvorm_label ;
45        BIND(IF(?lv != onz-zorg:instelling, ?leveringsvorm_label, 
46      		IF(?incl_behandeling, "Verblijf met behandeling", "Verblijf zonder behandeling"))
47      		AS ?leveringsvorm)		
48} 
49GROUP BY ?vestiging ?leveringsvorm
50ORDER BY ?vestiging ?leveringsvorm