2.1.5. Percentage kosten uitzendkrachten Personeel Niet In Loondienst

Concepten

• Grootboekpost

Relaties

• deel van
• gaat over
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde

Eigenschappen

• heeft datawaarde
• heeft datum

Instanties

• Aandeel werkgever premies sociale verzekeringen
• Aandeel werknemer premies sociale verzekeringen
• Berekende sociale kosten vakantiebijslag
• Korting / vrijlating basispremie WAO / werkgeverdeel Awf
• Leerling-verpleegkundig, -opvoedkundig en -verzorgend personeel
• Overgeboekte sociale kosten
• Pensioenkosten
• Personeel algemene en administratieve functies
• Personeel hotelfuncties
• Personeel patiënt- c.q. bewonergebonden functies
• Personeel terrein- en gebouwgebonden functies
• Vergoedingen voor niet in loondienst verrichte arbeid
• Ziektekostenverzekering

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ODB 2.1.5
2# Parameters: -
3# Ontologie: versie 2.1.1
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
8
9
10SELECT 
11   (SUM(?bedrag_pnil) AS ?kosten_pnil)
12   (SUM(?bedrag_pil) AS ?kosten_pil)
13   (100*(?kosten_pnil/?kosten_pil) AS ?percentage_pnil_tov_pil)
14
15{  
16    BIND ("2023-01-01"^^xsd:date AS ?start_periode)      
17    BIND ("2023-12-31"^^xsd:date AS ?eind_periode)
18    {
19        # Kosten personeel niet in loondienst
20        VALUES ?rubriek_pnil {
21            onz-fin:WBedOvpUik
22            onz-fin:WBedOvpUit
23            onz-fin:WBedOvpMaf
24            onz-fin:WBedOvpZzp
25            onz-fin:WBedOvpPay
26            onz-fin:WBedOvpOip
27
28            onz-fin:PM418000
29            }
30
31        ?post_pnil a onz-fin:Grootboekpost ;
32            onz-g:partOf ?rubriek_pnil ;
33            onz-g:isAbout ?kost_pnil ;
34            onz-g:hasDate ?datum_pnil .
35
36        ?kost_pnil onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?bedrag_pnil .
37        FILTER (?datum_pnil >= ?start_periode && ?datum_pnil <= ?eind_periode)
38        BIND(0 AS ?bedrag_pil) # zodat ?bedrag_pil nooit UNBOUND is en de som niet correct berekend wordt.
39
40    } UNION {
41        
42        # Kosten personeel in loondienst
43        VALUES ?rubriek_pil {
44        onz-fin:WPerLes
45        onz-fin:WPerSol
46
47        onz-fin:PM411000
48        onz-fin:PM412000
49        onz-fin:PM413000
50        onz-fin:PM414000
51        onz-fin:PM415000
52        onz-fin:PM422100
53        onz-fin:PM422300
54        onz-fin:PM422400
55        onz-fin:PM422410
56        onz-fin:PM422500
57        onz-fin:PM422600
58        onz-fin:PM422900
59        }
60
61        ?post_pil a onz-fin:Grootboekpost ;
62            onz-g:partOf ?rubriek_pil ;
63            onz-g:isAbout ?kost_pil ;
64            onz-g:hasDate ?datum_pil .
65
66        ?kost_pil onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?bedrag_pil .
67        FILTER (?datum_pil >= ?start_periode && ?datum_pil <= ?eind_periode)
68        BIND(0 AS ?bedrag_pnil) # zodat ?bedrag_pnil nooit UNBOUND is en de som niet correct berekend wordt.
69    }
70}
71