Let op: dit is een oudere versie van deze publicatie. Ga naar de laatste versie

Uitwisselprofiel NZa Basisinformatie kostenonderzoek

Versie:

Publicatiedatum:03-10-2023

Inwerkingtreding:03-10-2023

Bekijk bron

3.2. Gemiddeld bruto jaarsalaris per fte

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...Kopieer naar klembord
1# Indicator: NZA 3.2
2# Parameters: $(start_periode), $(eind_periode)
3# Ontologie: versie 2.1.1
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12
13SELECT ?teller ?noemer (?teller / ?noemer AS ?indicator)
14WHERE 
15{
16    {
17    SELECT ( SUM(?bedrag) AS ?teller ) 
18    WHERE 
19        {
20        BIND("2022-01-01"^^xsd:date AS ?start_periode)
21        BIND("2022-12-31"^^xsd:date AS ?eind_periode)
22
23        VALUES ?rubriek { 
24            onz-fin:WPerSol
25            onz-fin:WPerLes
26
27            onz-fin:PM411000
28            onz-fin:PM412000
29            onz-fin:PM413000
30            onz-fin:PM415000
31            onz-fin:PM422100
32            onz-fin:PM422300
33            onz-fin:PM422400
34            onz-fin:PM422410
35            onz-fin:PM422500
36            onz-fin:PM422600
37            onz-fin:PM422900
38
39            # ORT dient niet geincludeerd te worden
40            }   
41
42        ?post a onz-fin:Grootboekpost ;
43            onz-g:partOf ?rubriek ;
44            onz-g:isAbout ?kosten ;
45            onz-g:hasDate ?datum .
46
47        ?kosten onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?bedrag .
48
49        FILTER (?datum >= ?start_periode && ?datum <= ?eind_periode)
50        }
51    }
52    {
53    SELECT (SUM(?subtotaal) as ?noemer)
54    WHERE 
55        {
56        SELECT (SUM(?omvang_factor_corr) as ?subtotaal)
57        WHERE
58        { 
59            # definieer periode waarin overeenkomst geldig moet zijn
60            BIND("2022-01-01"^^xsd:date AS ?start_periode)
61            BIND("2022-12-31"^^xsd:date AS ?eind_periode)
62
63            ?overeenkomst 
64                onz-pers:heeftOpdrachtnemer ?persoon ;
65                a onz-pers:ArbeidsOvereenkomst ;
66                onz-g:hasPart ?omvang ;
67                onz-g:startDatum ?start .                
68            OPTIONAL {?overeenkomst onz-g:eindDatum ?end}
69            # alleen overeenkomsten in de gevraagde periode
70            FILTER (?start <= ?eind_periode && (!BOUND(?end) || ?end >= ?start_periode))
71
72            ?omvang
73                a onz-pers:ContractOmvang ;
74                onz-g:startDatum ?start_omvang ;
75                onz-g:isAbout ?omvang_waarde .
76            OPTIONAL {?omvang onz-g:eindDatum ?eind_omvang}
77            FILTER (?start_omvang <= ?eind_periode && (!BOUND(?eind_omvang) || ?eind_omvang >= ?start_periode))
78            ?omvang_waarde
79                onz-g:hasDataValue ?omvang_waarde_getal ;
80                onz-g:hasUnitOfMeasure ?omvang_waarde_eenheid .
81            ?omvang_waarde_eenheid
82                onz-pers:hasDenominatorQualityValue onz-g:Week ;
83                onz-pers:hasNumeratorQualityValue onz-g:Uur ;
84                onz-g:hasDataValue ?omvang_waarde_factor .
85
86            BIND(?omvang_waarde_getal/36*?omvang_waarde_factor AS ?omvang_waarde_rapportage)
87
88            # corrigeer wanneer start of eind van de contractomvang buiten de gevraagde periode valt
89            BIND(IF(?start_periode > ?start_omvang, ?start_periode, ?start_omvang) AS ?start_omvang_corr)
90            BIND(IF((?eind_periode < ?eind_omvang) || !BOUND(?eind_omvang), ?eind_periode, ?eind_omvang) AS ?eind_omvang_corr)
91
92            # Bereken gevraagd deel van de overeenkomst
93            BIND ((360 * (YEAR(?eind_periode + "P1D"^^xsd:duration) - YEAR(?start_periode))) +
94                (30 * (MONTH(?eind_periode + "P1D"^^xsd:duration) - MONTH(?start_periode))) +
95                (DAY(?eind_periode + "P1D"^^xsd:duration) - DAY(?start_periode))
96                AS ?dagen_periode)
97            BIND ((360 * (YEAR(?eind_omvang_corr + "P1D"^^xsd:duration) - YEAR(?start_omvang_corr))) +
98                (30 * (MONTH(?eind_omvang_corr + "P1D"^^xsd:duration) - MONTH(?start_omvang_corr))) +
99                (DAY(?eind_omvang_corr + "P1D"^^xsd:duration) - DAY(?start_omvang_corr))
100                AS ?dagen_overeenkomst)
101            BIND (?dagen_overeenkomst/?dagen_periode AS ?factor)
102            
103            # Bereken relevant deel van de omvangwaarde
104            BIND (?factor * ?omvang_waarde_rapportage AS ?omvang_factor_corr)
105        } 
106        GROUP BY ?overeenkomst ?omvang
107        }
108    }
109}```