5. Continentie

Concepten

• Afspraak continentie
• Verpleegproces
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft deelnemer
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• VV Beschermd verblijf met intensieve palliatief-terminale zorg
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
3PREFIX onz-org: <http://purl.org/ozo/onz-org#>
4PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
7
8SELECT
9    ?vestiging
10    ?teller
11    ?noemer
12    ?indicator
13{
14    {
15        SELECT
16            ?vestiging
17            (SUM(?inclusie_teller) AS ?teller_temp)
18            (COUNT(?client) AS ?noemer_temp)
19            (ROUND(100 * SUM(?inclusie_teller) / COUNT(?client)) AS ?indicator_temp)
20        {
21            {
22                SELECT 
23                    ?client
24                    (MAX(?start_proces) AS ?start_laatste_proces) #zodat meest recente vestiging gevonden kan worden
25                    (MAX(?tlr) AS ?inclusie_teller) #MAX zodat een client maar 1x mee kan tellen
26                {
27                    BIND("2022-01-01"^^xsd:date AS ?start_periode)    
28                    BIND("2022-12-31"^^xsd:date AS ?eind_periode)
29
30                    VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
31                    
32                    #selecteer de zorgprocessen die voldoen aan de inclusiecriteria
33                    ?zorgproces
34                        a onz-zorg:NursingProcess ;
35                        onz-g:hasParticipant ?client ;
36                        onz-g:definedBy/onz-g:hasPart ?zorgprofiel ;
37                        onz-g:startDatum ?start_proces .
38                        OPTIONAL {?zorgproces onz-g:eindDatum ?eind_proces}
39                    FILTER (?start_proces <= ?eind_periode && (!BOUND(?eind_proces) || ?eind_proces >= ?start_periode))
40
41                    #selecteer eventuele beleidsafspraken rondom toiletgang
42                    OPTIONAL {
43                        ?beleidsafspraak 
44                            a onz-zorg:AfspraakContinentie ;
45                            onz-g:isAbout ?client ;
46                            onz-g:startDatum ?datum .
47                        FILTER (?datum <= ?eind_periode)
48                    }
49                    BIND(IF(BOUND(?beleidsafspraak),1,0) AS ?tlr)
50                } 
51                GROUP BY ?client
52            }
53            #Vind de laatste vestiging binnen de verslagperiode en koppel deze aan de client
54            ?laatsteproces 
55                onz-g:hasParticipant ?client ;
56                onz-g:startDatum ?start_laatste_proces ;
57                onz-g:hasPerdurantLocation ?locatie .
58            ?locatie 
59                onz-g:partOf* ?vestiging_uri .
60            ?vestiging_uri 
61                a onz-org:Vestiging ;
62                onz-g:identifiedBy ?vest_nr .
63            ?vest_nr
64                a onz-org:Vestigingsnummer ;
65                onz-g:hasDataValue ?vestiging .
66        }
67        GROUP BY ?vestiging
68    }
69    #Corrigeer voor waarnemingen kleiner dan 10
70    #Houd rekening met een teller die mogelijk groter is dan de noemer
71    BIND (IF(?teller_temp < 10, "Waarneming kleiner dan 10", ?teller_temp) AS ?teller)
72    BIND (IF(?noemer_temp < 10, "Waarneming kleiner dan 10", ?noemer_temp) AS ?noemer)
73    BIND (IF(?teller_temp < 10, "Waarneming kleiner dan 10", ?indicator_temp) AS ?indicator)
74}