2.4.1. Percentage instroom

Concepten

• Arbeidsovereenkomst
• Zorgverlener (functie)

Relaties

• gaat over
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ODB Personele samenstelling 2.4.1
2# Parameters: -
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8
9SELECT 
10	(SUM(coalesce(?instroom, 0)) AS ?teller)
11	((SUM(?count_start) + SUM(?count_eind))/2 AS ?noemer) 
12    (ROUND( 100 * (SUM(coalesce(?instroom, 0))/((SUM(?count_start) + SUM(?count_eind))/2))) AS ?indicator)
13WHERE
14{
15    {
16        SELECT
17            ?persoon 
18            (MAX(?geldig_verleden) AS ?count_start)
19            (MAX(?geldig_eind) AS ?count_eind)
20        WHERE 
21        { 
22            BIND ("2022-12-31"^^xsd:date AS ?peildatum)
23            BIND (?peildatum - "P1Y"^^xsd:duration AS ?verleden)
24        
25            # selecteer werkovereenkomsten waarbij werknemer een zorgverlenerfunctie heeft
26            ?overeenkomst 
27                    a onz-pers:ArbeidsOvereenkomst ;
28                    onz-pers:heeftOpdrachtnemer ?persoon ;
29                    onz-g:isAbout ?functie .
30            ?functie 
31                    a onz-pers:ZorgverlenerFunctie ;
32                    onz-g:startDatum ?start_overeenkomst .
33            OPTIONAL {?functie onz-g:eindDatum ?eind_overeenkomst}
34
35            BIND(IF(?start_overeenkomst <= ?peildatum && (?eind_overeenkomst >= ?peildatum || !BOUND(?eind_overeenkomst)), 1, 0) AS ?geldig_eind)
36            BIND(IF(?start_overeenkomst <= ?verleden && (?eind_overeenkomst >= ?verleden || !BOUND(?eind_overeenkomst)), 1, 0) AS ?geldig_verleden)
37        
38        } GROUP BY ?persoon
39    } 
40BIND(IF(?count_start=0 && ?count_eind=1, 1, 0) AS ?instroom)
41}