2.2.1. Percentage fte per niveau

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• ODB Kwalificatiewaarde
• Zorgverlener (functie)

Relaties

• gaat over
• gedefinieerd door
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• heeftEindTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ODB Personele samenstelling 2.2.1
2# Parameters: -
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9
10SELECT 
11	?kwalificatie (SUM(?uren)/1692 AS ?teller) 
12	(?uren_tot/1692 AS ?noemer) 
13	(SUM(?uren)/?uren_tot * 100 AS ?indicator)
14WHERE 
15{
16    {
17        SELECT DISTINCT 
18        	?gewerkte_periode 
19        	?kwalificatie 
20        	?uren        
21        WHERE 
22        { 
23            BIND ("2022-01-01"^^xsd:date AS ?start_periode)
24            BIND ("2022-12-31"^^xsd:date AS ?eind_periode) 
25
26            # selecteer aantal gewerkte uren binnen periode die gekoppeld zijn aan werkovereenkomst 
27            ?gewerkte_periode 
28             	a onz-pers:GewerktePeriode ;
29              	onz-g:hasBeginTimeStamp ?start_gewerktDT ;
30               	onz-g:hasEndTimeStamp ?eind_gewerktDT ;
31               	onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?uren ;
32                onz-g:definedBy ?overeenkomst .
33            BIND(STRDT(SUBSTR(STR(?start_gewerktDT),1,10), xsd:date) AS ?start_gewerkt)
34            BIND(STRDT(SUBSTR(STR(?eind_gewerktDT),1,10), xsd:date) AS ?eind_gewerkt)
35            
36            # selecteer gewerkte tijd in de gevraagde periode
37            FILTER(?start_gewerkt >= ?start_periode && ?eind_gewerkt <= ?eind_periode)
38  
39           	# selecteer werkovereenkomsten waarbij werknemer een zorgverlenerfunctie heeft
40            ?overeenkomst 
41                a onz-pers:ArbeidsOvereenkomst ;
42                onz-pers:heeftOpdrachtnemer ?werknemer ;
43                onz-g:isAbout ?functie .
44            ?functie 
45                a onz-pers:ZorgverlenerFunctie ;
46                a/onz-g:hasQuality/onz-g:hasQualityValue ?functie_niveau ;
47                onz-g:startDatum ?start_functie.
48                OPTIONAL {?functie onz-g:eindDatum ?eind_functie}
49                FILTER (?start_functie <= ?start_gewerkt && ((?eind_functie >= ?eind_gewerkt)||(!BOUND(?eind_functie))))
50            ?functie_niveau 
51                a onz-pers:ODBKwalificatieWaarde ;
52                rdfs:label ?kwalificatie .            
53        }
54    }
55    { 
56        SELECT 
57        	(SUM(?uren) AS ?uren_tot)
58        WHERE 
59        {
60            {
61                SELECT DISTINCT 
62                	?start_periode 
63                	?eind_periode 
64                	?gewerkte_periode 
65                	?uren        
66                WHERE 
67                { 
68                    BIND ("2022-01-01"^^xsd:date AS ?start_periode)
69                    BIND ("2022-12-31"^^xsd:date AS ?eind_periode)  
70                    
71                    # selecteer aantal gewerkte uren binnen periode die gekoppeld zijn aan werkovereenkomst 
72                    ?gewerkte_periode 
73                        a onz-pers:GewerktePeriode ;
74                        onz-g:hasBeginTimeStamp ?start_gewerktDT ;
75                        onz-g:hasEndTimeStamp ?eind_gewerktDT ;
76                        onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?uren ;
77                        onz-g:definedBy ?overeenkomst .
78                    BIND(STRDT(SUBSTR(STR(?start_gewerktDT),1,10), xsd:date) AS ?start_gewerkt)
79                    BIND(STRDT(SUBSTR(STR(?eind_gewerktDT),1,10), xsd:date) AS ?eind_gewerkt)
80
81                    
82                    # selecteer gewerkte tijd in de gevraagde periode
83                    FILTER(?start_gewerkt >= ?start_periode && ?eind_gewerkt <= ?eind_periode)
84                    
85                    # selecteer werkovereenkomsten waarbij werknemer een zorgverlenerfunctie heeft
86                    ?overeenkomst 
87                        a onz-pers:ArbeidsOvereenkomst ;
88                        onz-g:isAbout/a onz-pers:ZorgverlenerFunctie .  
89                }
90            }
91        } 
92    }
93} 
94GROUP BY ?kwalificatie ?uren_tot
95ORDER BY ?kwalificatie