Uitwisselprofiel Zorginstituut Openbaarmaking kwaliteitsindicatoren verpleeghuiszorg

Versie:

Publicatiedatum:20-06-2023

Inwerkingtreding:01-07-2023

Bekijk bron

6. Aandacht voor eten en drinken voedselvoorkeuren client

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
3PREFIX onz-org: <http://purl.org/ozo/onz-org#>
4PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
7
8SELECT
9    ?vestiging
10    ?teller
11    ?noemer
12    ?indicator
13{
14    {
15        SELECT
16            ?vestiging
17            (SUM(?inclusie_teller) AS ?teller_temp)
18            (COUNT(?client) AS ?noemer_temp)
19            (ROUND(100 * SUM(?inclusie_teller) / COUNT(?client)) AS ?indicator_temp)
20        {
21            {
22                SELECT 
23                    ?client
24                    (MAX(?start_proces) AS ?start_laatste_proces) #zodat meest recente vestiging gevonden kan worden
25                    (MAX(?tlr) AS ?inclusie_teller) #MAX zodat een client maar 1x mee kan tellen
26                {
27                    BIND("2022-12-31"^^xsd:date AS ?peildatum)
28                    BIND(?peildatum - "P6M"^^xsd:duration + "P1D"^^xsd:duration AS ?start_periode)
29                    BIND(?peildatum AS ?eind_periode)
30
31                    VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
32                    
33                    #selecteer de zorgprocessen die voldoen aan de inclusiecriteria
34                    ?zorgproces
35                        a onz-zorg:NursingProcess ;
36                        onz-g:hasParticipant ?client ;
37                        onz-g:definedBy/onz-g:hasPart ?zorgprofiel ;
38                        onz-g:startDatum ?start_proces .
39                        OPTIONAL {?zorgproces onz-g:eindDatum ?eind_proces}
40                    FILTER (?start_proces <= ?eind_periode && (!BOUND(?eind_proces) || ?eind_proces >= ?start_periode))
41
42                    #selecteer eventuele beleidsafspraken rondom voedselvoorkeuren
43                    OPTIONAL {
44                        ?beleidsafspraak 
45                            a onz-zorg:AfspraakVoedselvoorkeuren ;
46                            onz-g:isAbout ?client ;
47                            onz-g:startDatum ?datum .
48                        FILTER (?datum >= ?start_periode && ?datum <= ?eind_periode)
49                    }
50                    BIND(IF(BOUND(?beleidsafspraak),1,0) AS ?tlr)
51                } 
52                GROUP BY ?client
53            }
54            #Vind de laatste vestiging binnen de verslagperiode en koppel deze aan de client
55            ?laatsteproces 
56                onz-g:hasParticipant ?client ;
57                onz-g:startDatum ?start_laatste_proces ;
58                onz-g:hasPerdurantLocation ?locatie .
59            ?locatie 
60                onz-g:partOf* ?vestiging_uri .
61            ?vestiging_uri 
62                a onz-org:Vestiging ;
63                onz-g:identifiedBy ?vest_nr .
64            ?vest_nr
65                a onz-org:Vestigingsnummer ;
66                onz-g:hasDataValue ?vestiging .
67        }
68        GROUP BY ?vestiging
69    }
70    #Corrigeer voor waarnemingen kleiner dan 10
71    #Houd rekening met een teller die mogelijk groter is dan de noemer
72    BIND (IF(?teller_temp < 10, "Waarneming kleiner dan 10", ?teller_temp) AS ?teller)
73    BIND (IF(?noemer_temp < 10, "Waarneming kleiner dan 10", ?noemer_temp) AS ?noemer)
74    BIND (IF(?teller_temp < 10, "Waarneming kleiner dan 10", ?indicator_temp) AS ?indicator)
75}