2.1.4. Percentage inzet uitzendkrachten Personeel Niet in Loondienst (PNIL)

Concepten

• Arbeidsovereenkomst
• Inhuurovereenkomst
• Uitzendovereenkomst
• Zorgverlener (functie)

Relaties

• gaat over
• gedefinieerd door
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• heeftEindTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ODB Personele samenstelling 2.1.4
2# Parameters: -
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8
9SELECT 
10	(SUM(?pnil_uren)/1692 AS ?teller) 
11	(SUM(?uren)/1692 AS ?noemer) 
12	(SUM(?pnil_uren)/SUM(?uren)*100 AS ?indicator)
13WHERE 
14{
15    SELECT DISTINCT 
16		?gewerkteperiode 
17		?uren 
18		?pnil_uren
19    WHERE 
20	{ 
21    	# definieer periode waarin overeenkomst geldig moet zijn
22        BIND("2022-01-01"^^xsd:date AS ?start_periode)
23        BIND("2022-12-31"^^xsd:date AS ?eind_periode)
24
25        ?overeenkomst 
26			onz-g:startDatum ?start_overeenkomst ;
27            onz-g:isAbout/a onz-pers:ZorgverlenerFunctie .           # filter op zorgverlener
28        OPTIONAL {?overeenkomst onz-g:eindDatum ?eind_overeenkomst}
29        FILTER(?start_overeenkomst <= ?eind_periode && ((?eind_overeenkomst >= ?start_periode) || (!BOUND(?eind_overeenkomst))))
30
31		# selecteer uren van gewerkte periode
32        ?gewerkteperiode 
33			onz-g:definedBy ?overeenkomst ;
34            onz-g:hasBeginTimeStamp ?start_werkDT ;
35            onz-g:hasEndTimeStamp ?eind_werkDT ;
36            onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?uren ;
37        BIND(STRDT(SUBSTR(STR(?start_werkDT),1,10), xsd:date) AS ?start_werk)
38        BIND(STRDT(SUBSTR(STR(?eind_werkDT),1,10), xsd:date) AS ?eind_werk)
39        
40		# filter in gewenste tijsdperiode
41        FILTER(?start_werk >= ?start_periode && ?eind_werk <= ?eind_periode)
42
43        VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomst onz-pers:InhuurOvereenkomst onz-pers:UitzendOvereenkomst}
44        
45		?overeenkomst a ?type_overeenkomst .
46        
47        # ken PNIL uren toe aan inhuur- en uitzendovereenkomsten
48        BIND(IF(?type_overeenkomst = onz-pers:InhuurOvereenkomst || ?type_overeenkomst = onz-pers:UitzendOvereenkomst, ?uren, 0) AS ?pnil_uren)
49       } 
50}