Let op: dit is een oudere versie van deze publicatie. Ga naar de laatste versie

Uitwisselprofiel Zorginstituut Openbaarmaking kwaliteitsindicatoren verpleeghuiszorg

Versie:

Publicatiedatum:20-06-2023

Inwerkingtreding:01-07-2023

Bekijk bron

2.1.2. Aantal fte

Concepten

Relaties

Eigenschappen

Instanties

Week

SPARQL query

Code gekopieerd
...Kopieer naar klembord
1# Indicator: ODB Personele samenstelling 2.1.2
2# Parameters: -
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9
10SELECT 
11    (SUM(?aantal) AS ?indicator) 
12    ?eenheid
13WHERE 
14{
15    {
16        SELECT DISTINCT 
17            ?start_periode 
18            ?eind_periode 
19            ?gewerkte_periode 
20            ?uren
21        WHERE 
22        { 
23            BIND ("2022-01-01"^^xsd:date AS ?start_periode)
24            BIND ("2022-12-31"^^xsd:date AS ?eind_periode)  
25            
26            # selecteer aantal gewerkte uren binnen periode die gekoppeld zijn aan werkovereenkomst 
27            ?gewerkte_periode 
28                a onz-pers:GewerktePeriode ;
29                onz-g:hasBeginTimeStamp ?start_gewerktDT ;
30                onz-g:hasEndTimeStamp ?eind_gewerktDT ;
31                onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?uren ;
32                onz-g:definedBy ?overeenkomst .
33            BIND(STRDT(SUBSTR(STR(?start_gewerktDT),1,10), xsd:date) AS ?start_gewerkt)
34            BIND(STRDT(SUBSTR(STR(?eind_gewerktDT),1,10), xsd:date) AS ?eind_gewerkt)
35    		# selecteer gewerkte tijd in de gevraagde periode
36            FILTER(?start_gewerkt >= ?start_periode && ?eind_gewerkt <= ?eind_periode)
37
38            # selecteer werkovereenkomsten waarbij werknemer een zorgverlenerfunctie heeft
39            ?overeenkomst 
40                a onz-pers:ArbeidsOvereenkomst ;
41                onz-g:isAbout/a onz-pers:ZorgverlenerFunctie .       
42        }
43    }
44    
45    ?e 
46     	a onz-g:UnitOfWorkload ;
47       	onz-g:hasDataValue ?corr_factor ;
48       	onz-pers:hasDenominatorQualityValue onz-g:Week ;
49       	rdfs:label ?eenheid .
50        
51    BIND ((360 * (YEAR(?eind_periode + "P1D"^^xsd:duration) - YEAR(?start_periode))) +
52    (30 * (MONTH(?eind_periode + "P1D"^^xsd:duration) - MONTH(?start_periode))) +
53    (DAY(?eind_periode + "P1D"^^xsd:duration) - DAY(?start_periode)) AS ?dagen_periode)
54    
55    BIND (?uren/(?dagen_periode/360*47)/?corr_factor AS ?aantal)
56} 
57GROUP BY ?eenheid```