1.2. Aantal personeelsleden op een peildatum

Concepten

• Arbeidsovereenkomst
• Bedrijf
• Functie in organisatie-rol
• Inhuurovereenkomst
• Mens
• Oproepovereenkomst
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
3PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
4PREFIX onz-org: <http://purl.org/ozo/onz-org#>
5PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
6PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8
9SELECT 
10    ?Vestiging 
11    (SUM(?zorg_boolean) AS ?Zorg) 
12    (COUNT(?persoon) - SUM(?zorg_boolean) AS ?Niet_zorg)
13    (COUNT(?persoon) AS ?Totaal) 
14{
15    {
16        SELECT ?persoon ?Vestiging (MAX(?zorgfunctie) AS ?zorg_boolean)
17        {
18            #Bepaal de peildatum
19            BIND("2022-01-01"^^xsd:date AS ?peildatum)
20            
21            #Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
22            VALUES ?personeels_overeenkomst 
23      		{ 
24        		onz-pers:ArbeidsOvereenkomst
25        		onz-pers:OproepOvereenkomst
26        		onz-pers:UitzendOvereenkomst
27        		onz-pers:InhuurOvereenkomst
28      		}
29
30            #Selecteer alle personeelsleden (personen met een arbeids-, oproep,- uitzend,- of inhuurovereenkomst) binnen de meetperiode
31            ?persoon
32                a onz-g:Human ;
33                ^onz-pers:heeftOpdrachtnemer ?overeenkomst .
34            ?overeenkomst
35                a ?personeels_overeenkomst ;
36                onz-g:isAbout ?functie ;
37                onz-g:isAbout ?locatie ;
38                onz-g:startDatum ?start_overeenkomst .
39                OPTIONAL {?overeenkomst onz-g:eindDatum ?eind_overeenkomst}
40      		    FILTER (?start_overeenkomst <= ?peildatum && ((?eind_overeenkomst >= ?peildatum)||(!BOUND(?eind_overeenkomst))))
41
42            #Bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
43            {
44                ?locatie onz-g:partOf* ?vestiging_uri .
45                ?vestiging_uri 
46                    a onz-org:Vestiging ;
47                    onz-g:identifiedBy ?vest_nr.
48                ?vest_nr
49                    a onz-org:Vestigingsnummer ;
50                    onz-g:hasDataValue ?Vestiging .
51            } UNION {
52                #Includeer ook de organisatie als geheel en label deze als vestiging
53                ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
54                ?organisatie_uri 
55                    a onz-g:Business ;
56                    rdfs:label ?Organisatie .
57                BIND(CONCAT('Totaal ',?Organisatie) AS ?Vestiging)
58            }
59            
60            #Bepaal of de functie op de overeenkomst van het type ZorgverlenerFunctie is
61            ?functie 
62                a onz-g:OccupationalPositionRole ;
63                a ?type_functie .
64            BIND(IF(?type_functie = onz-pers:ZorgverlenerFunctie, 1, 0) AS ?zorgfunctie)
65        } 
66        GROUP BY ?persoon ?Vestiging
67    }
68} GROUP BY ?Vestiging```