13.2. Percentage uitstroom personeel in loondienst

Concepten

• Arbeidsovereenkomst
• Inhuurovereenkomst
• Uitzendovereenkomst
• Zorgverlener (functie)

Relaties

• gaat over
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 13.2
2# Parameters: $(peildatum)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX onz-g: <http://purl.org/ozo/onz-g#>
10PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
11
12SELECT 
13	(COUNT(?werknemer) AS ?noemer)
14    (SUM(?uitstroom) AS ?teller)
15    (xsd:integer(ROUND(100*(SUM(?uitstroom)/COUNT(?werknemer)))) AS ?indicator)
16WHERE
17{
18    {
19        SELECT 
20            ?werknemer
21            (MIN(?weg) AS ?uitstroom)
22        {
23            BIND($(peildatum) AS ?peildatum)
24            BIND((?peildatum - "P1Y"^^xsd:duration) AS ?peildatum_eerder)
25
26            # Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
27            VALUES ?personeels_overeenkomst 
28            { 
29                onz-pers:ArbeidsOvereenkomst
30                onz-pers:UitzendOvereenkomst
31                onz-pers:InhuurOvereenkomst
32            }
33            ?overeenkomst 
34                a ?personeels_overeenkomst ; # Alleen personeel
35                onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ; # Alleen Zorgverlener
36                onz-pers:heeftOpdrachtnemer ?werknemer ;
37                onz-g:startDatum ?start_overeenkomst .
38            OPTIONAL {
39                ?overeenkomst onz-g:eindDatum ?eind_overeenkomst
40            }
41            # Noemer is de populatie die aan het begin van de periode (?peildatum_eerder) behoorde tot personeel
42            FILTER (?start_overeenkomst <= ?peildatum_eerder && (?eind_overeenkomst >= ?peildatum_eerder || !BOUND(?eind_overeenkomst)))
43            
44            # Teller is populatie die op peildatum is uitgestroomd
45            # Kijk of er op peildatum nog steeds een arbeidsovereenkomst was die aan de voorwaarden voldoet
46            OPTIONAL {
47                ?overeenkomst_peildatum
48                    a ?personeels_overeenkomst ; #Alleen personeel
49                    onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ; #Alleen Zorgverlener
50                    onz-pers:heeftOpdrachtnemer ?werknemer ;
51                    onz-g:startDatum ?start_overeenkomst_peildatum .
52                OPTIONAL {
53                    ?overeenkomst_peildatum onz-g:eindDatum ?eind_overeenkomst_peildatum
54                }
55                FILTER (?start_overeenkomst_peildatum <= ?peildatum && (?eind_overeenkomst_peildatum >= ?peildatum || !BOUND(?eind_overeenkomst_peildatum)))
56            }
57            BIND(IF(BOUND(?overeenkomst_peildatum), 0, 1) AS ?weg)
58        }   
59        GROUP BY ?werknemer
60    }
61}