12.2.4 Verzuimfrequentie (incl. zwangerschapsverlof) Q4 2023

Concepten

• Arbeidsovereenkomst
• Bedrijf
• Inhuurovereenkomst
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Ziekteperiode
• Zorgverlener (functie)
• Zwangerschapsverlof

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deelnemer
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 12.2
2# Parameters: ($kwartaal)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX onz-g: <http://purl.org/ozo/onz-g#>
10PREFIX onz-org: <http://purl.org/ozo/onz-org#>
11PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
12
13SELECT 
14    ?vestiging
15    (COUNT(?overeenkomst) AS ?aantal_arbeidsovereenkomsten)
16    (SUM(?meldingen) AS ?aantal_meldingen)
17    (SUM(?meldingen) / COUNT(?overeenkomst) AS ?verzuimfrequentie)
18{
19    {
20        SELECT 
21            DISTINCT ?overeenkomst 
22            ?vestiging 
23            (SUM(?melding) AS ?meldingen)
24        {
25            BIND('Q4' AS ?kwartaal)
26            BIND(IF(?kwartaal = 'Q1', '2023-01-01'^^xsd:date, 
27                IF(?kwartaal = 'Q2', '2023-04-01'^^xsd:date,
28                IF(?kwartaal = 'Q3', '2023-07-01'^^xsd:date,
29                IF(?kwartaal = 'Q4', '2023-10-01'^^xsd:date, 
30                '')))) AS ?start_periode)
31            BIND(?start_periode + "P3M"^^xsd:duration - "P1D"^^xsd:duration AS ?eind_periode)
32            # Keuze in-/exclusief zwangerschapsverlog
33            VALUES ?type_verzuim
34            { 
35                onz-pers:ZiektePeriode
36                onz-pers:ZwangerschapsVerlof
37            }
38
39            # Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
40            VALUES ?personeels_overeenkomst 
41            { 
42                onz-pers:ArbeidsOvereenkomst
43                onz-pers:UitzendOvereenkomst
44                onz-pers:InhuurOvereenkomst
45            }
46            ?overeenkomst 
47                a ?personeels_overeenkomst ; #Alleen personeel
48                onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ; #Alleen Zorgverlener
49                onz-pers:heeftOpdrachtnemer ?werknemer ;
50                onz-g:isAbout ?locatie ;
51                onz-g:startDatum ?start_overeenkomst .
52            OPTIONAL {
53                ?overeenkomst onz-g:eindDatum ?eind_overeenkomst
54            }
55            FILTER (?start_overeenkomst <= ?eind_periode && (!BOUND(?eind_overeenkomst) || ?eind_overeenkomst >= ?start_periode))
56
57            OPTIONAL {
58                ?werknemer
59                    ^onz-g:hasParticipant ?ziekteperiode .
60                ?ziekteperiode
61                    a ?type_verzuim ;
62                    onz-g:startDatum ?start_ziekte .
63                # Ziektemelding moet vallen binnen de meetperiode EN per overeenkomst binnen de geldigheid van die overeenkomst
64                FILTER (?start_ziekte >= ?start_periode && ?start_ziekte <= ?eind_periode)
65                FILTER (?start_ziekte >= ?start_overeenkomst && (?start_ziekte <= ?eind_overeenkomst || !BOUND(?eind_overeenkomst)))
66            }
67            BIND(IF(BOUND(?ziekteperiode), 1, 0) AS ?melding)
68            #Bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
69            {
70                ?locatie onz-g:partOf* ?vestiging_uri .
71                ?vestiging_uri 
72                    a onz-org:Vestiging ;
73                    onz-g:identifiedBy ?vest_nr.
74                ?vest_nr
75                    a onz-org:Vestigingsnummer ;
76                    onz-g:hasDataValue ?vestiging .
77            } UNION {
78                #Includeer ook de organisatie als geheel en label deze als vestiging
79                ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
80                ?organisatie_uri 
81                    a onz-g:Business ;
82                    rdfs:label ?Organisatie .
83                BIND(CONCAT('Totaal ',?Organisatie) AS ?vestiging)
84            }
85        }
86        GROUP BY ?overeenkomst ?vestiging
87    }
88}
89GROUP BY ?vestiging