2.1.0 Aantal ingezette uren personeel

Concepten

• Arbeidsovereenkomst
• Bedrijf
• Gewerkte periode
• Gewerkte tijd
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• heeft datawaarde
• heeftBeginTijd
• heeftEindTijd

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 2.1
2# Parameters: ($kwartaal)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13    ?Vestiging
14    (SUM(?inzet_uren) AS ?indicator)
15{
16    {
17        SELECT DISTINCT
18            ?locatie
19            ?inzet
20            ?gewerkte_tijd
21        {   
22            BIND(($kwartaal) AS ?kwartaal)
23            BIND(IF(?kwartaal = 'Q1', '2022-01-01'^^xsd:date, 
24                IF(?kwartaal = 'Q2', '2022-04-01'^^xsd:date,
25                IF(?kwartaal = 'Q3', '2022-07-01'^^xsd:date,
26                IF(?kwartaal = 'Q4', '2022-10-01'^^xsd:date, 
27                '')))) AS ?start_periode)
28            BIND(?start_periode + "P3M"^^xsd:duration - "P1D"^^xsd:duration AS ?eind_periode)
29            ?inzet 
30                a onz-pers:GewerktePeriode ;
31                onz-g:definedBy ?overeenkomst ;
32                onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
33                onz-g:hasEndTimeStamp ?eind_inzet_datetime ;
34                onz-g:hasQuality ?gewerkte_tijd .
35            OPTIONAL{?inzet onz-g:hasPerdurantLocation ?locatie_werk} 
36            # Als begin- en endTimeStamp van type dateTime zijn dan omzetten zodat vergeleken kan worden met start en eind period
37            BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
38            BIND(STRDT(SUBSTR(STR(?eind_inzet_datetime), 1, 10), xsd:date) AS ?eind_inzet)
39            FILTER (?start_inzet >= ?start_periode && ?eind_inzet <= ?eind_periode)
40            ?overeenkomst
41                a onz-pers:ArbeidsOvereenkomst ;
42                onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ;
43                onz-g:isAbout ?locatie_contract .
44            ?locatie_contract a onz-g:StationaryArtifact .
45            BIND(IF(!BOUND(?locatie_werk), ?locatie_contract, ?locatie_werk) AS ?locatie)
46        }
47    }
48    # Bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
49    {
50        ?locatie onz-g:partOf* ?vestiging_uri .
51        ?vestiging_uri 
52            a onz-org:Vestiging ;
53            onz-g:identifiedBy ?vest_nr.
54        ?vest_nr a onz-org:Vestigingsnummer ;
55            onz-g:hasDataValue ?Vestiging .
56    } UNION {
57        # Includeer ook de organisatie als geheel en label deze als vestiging
58        ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
59        ?organisatie_uri 
60            a onz-g:Business ;
61            rdfs:label ?Organisatie .
62        BIND(CONCAT('Totaal ',?Organisatie) AS ?Vestiging)
63    }
64    ?gewerkte_tijd
65        a onz-pers:GewerkteTijd ;
66        onz-g:hasQualityValue/onz-g:hasDataValue ?inzet_uren .
67}
68GROUP BY ?Vestiging