14.3.0 Aantal cliënten per zorgprofiel per leveringsvorm

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
3PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
4PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6
7SELECT
8	?zorgprofiel
9	(SUM(?max_vmb) AS ?verblijf_met_behandeling)
10	(SUM(?max_vzb) AS ?verblijf_zonder_behandeling)
11	(SUM(?max_vpt) AS ?volledig_pakket_thuis)
12	(SUM(?max_mpt) AS ?modulair_pakket_thuis)
13	(SUM(?max_pgb) AS ?persoonsgebonden_budget)
14	(SUM(?max_vmb) + SUM(?max_vzb) + SUM(?max_vpt) + SUM(?max_mpt) + SUM(?max_pgb) AS ?Totaal)
15{
16    {
17        SELECT
18            ?client
19            ?zorgprofiel
20            (MAX(?vmb) AS ?max_vmb)
21            (MAX(?vzb) AS ?max_vzb)
22            (MAX(?vpt) AS ?max_vpt)
23            (MAX(?mpt) AS ?max_mpt)
24            (MAX(?pgb) AS ?max_pgb)
25        WHERE
26        { 
27            BIND ($(peildatum) AS ?peildatum)
28            VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
29
30            #selecteer de zorgprocessen op de (sub)locaties die voldoen aan de inclusiecriteria
31            ?zorgproces
32                a onz-zorg:NursingProcess ;
33                onz-g:definedBy ?indicatie ;
34                onz-g:startDatum ?start_zorgproces .
35                OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
36                FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces))))
37            #selecteer de bijbehordene indicatie, om unieke clienten te kunnen bepalen
38            ?indicatie 
39                onz-g:hasPart ?zorgprofiel ;
40                onz-g:hasPart ?lv ;
41                onz-g:isAbout ?client .
42                OPTIONAL {?indicatie onz-zorg:heeftIndicatieBehandeling ?behandeling}
43                BIND(IF(BOUND(?behandeling), ?behandeling, "false"^^xsd:boolean) AS ?incl_behandeling)
44            ?client a onz-g:Human .
45            ?lv
46                a onz-zorg:Leveringsvorm .
47            BIND(IF(?lv = onz-zorg:instelling && ?incl_behandeling, 1, 0) AS ?vmb)
48            BIND(IF(?lv = onz-zorg:instelling && !?incl_behandeling, 1, 0) AS ?vzb)
49            BIND(IF(?lv = onz-zorg:vpt, 1, 0) AS ?vpt)
50            BIND(IF(?lv = onz-zorg:mpt, 1, 0) AS ?mpt)
51            BIND(IF(?lv = onz-zorg:pgb, 1, 0) AS ?pgb)
52        } 
53        GROUP BY ?client ?zorgprofiel
54    }
55}
56GROUP BY ?zorgprofiel