15.4.2.4 Aantal cliënten met een Wlz-indicatie per sector - peildatum 1-10-2023

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.2.4
2# Parameters: 
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT ?vestiging        
12        (SUM(?vv) as ?aantal_vv)
13        (SUM(?lg) as ?aantal_lg)
14        (SUM(?lvg) as ?aantal_lvg)
15        (SUM(?vg) as ?aantal_vg)
16        (SUM(?zgaud) as ?aantal_zgaud)
17        (SUM(?zgvis) as ?aantal_zgvis)
18        (SUM(?ggzb) as ?aantal_ggzb)
19        (SUM(?ggzw) as ?aantal_ggzw)    
20WHERE
21{
22        BIND ("2023-10-01"^^xsd:date AS ?peildatum)
23
24        #selecteer de zorgprocessen die voldoen aan de inclusiecriteria
25        ?zorgproces
26            a onz-zorg:NursingProcess ;
27            onz-g:definedBy ?indicatie ;
28            onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie ; # locatie bevat niet alleen vestigingen
29            onz-g:startDatum ?start_zorgproces .
30            OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
31            FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces))))
32           
33        {
34            ?locatie 
35                a onz-org:Vestiging ;
36                onz-g:identifiedBy ?vest_nr.
37            	?vest_nr a onz-org:Vestigingsnummer ;
38                     onz-g:hasDataValue ?vestiging .
39        } UNION {
40            #Includeer ook de organisatie als geheel en label deze als vestiging
41            ?locatie onz-org:vestigingVan ?organisatie_uri .
42            ?organisatie_uri 
43                a onz-g:Business ;
44                rdfs:label ?Organisatie .
45            BIND(CONCAT('Totaal ',?Organisatie) AS ?vestiging)
46        }
47
48    	#selecteer de bijbehorende indicatie, om unieke clienten te kunnen bepalen
49        ?indicatie 
50            a onz-zorg:WlzIndicatie ;
51            onz-g:hasPart/onz-g:isAbout ?sector ;
52            onz-g:isAbout ?client .
53        
54        ?sector
55            a onz-zorg:LangdurigeZorgSector .
56        ?client a onz-g:Human .
57    
58        #Per financieringsstroom
59        BIND(IF(?sector = onz-zorg:VV, 1, 0) AS ?vv)
60        BIND(IF(?sector = onz-zorg:LG, 1, 0) AS ?lg)
61        BIND(IF(?sector = onz-zorg:LVG, 1, 0) AS ?lvg)
62        BIND(IF(?sector = onz-zorg:VG, 1, 0) AS ?vg)
63        BIND(IF(?sector = onz-zorg:ZGAUD, 1, 0) AS ?zgaud)
64        BIND(IF(?sector = onz-zorg:ZGVIS, 1, 0) AS ?zgvis)
65        BIND(IF(?sector = onz-zorg:GGZ-B, 1, 0) AS ?ggzb)
66        BIND(IF(?sector = onz-zorg:GGZ-W, 1, 0) AS ?ggzw)    
67} 
68GROUP BY ?vestiging
69ORDER BY ?vestiging
70