3.1.0 Percentage arbeidsovereenkomsten voor bepaalde tijd op een peildatum

Concepten

• Arbeidsovereenkomst bepaalde tijd
• Arbeidsovereenkomst onbepaalde tijd
• Bedrijf
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 3.1
2# Parameters: ($peildatum)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12	?vestiging
13    (SUM(?bepaald) AS ?aantal_bepaalde_tijd)
14    (COUNT(?personeel) AS ?totaal)
15    (?aantal_bepaalde_tijd/?totaal * 100 AS ?percentage_bepaalde_tijd)
16{
17    SELECT DISTINCT
18        ?vestiging
19        ?personeel
20        ?bepaald
21    {     
22        # definieer peildatum
23        BIND(($peildatum) AS ?peildatum)
24
25        # selecteer personen met arbeidsovereenkomst (on)bepaalde tijd
26        VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomstBepaaldeTijd onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd}
27        ?arbeidsovereenkomst a ?type_overeenkomst ;
28            onz-g:startDatum ?start_overeenkomst ;
29            onz-g:isAbout ?locatie ;
30            onz-pers:heeftOpdrachtnemer ?personeel .
31        OPTIONAL {?arbeidsovereenkomst onz-g:eindDatum ?eind_overeenkomst}
32            
33        # filter op peildatum
34        FILTER (?start_overeenkomst <= ?peildatum && (!BOUND(?eind_overeenkomst) || ?eind_overeenkomst >= ?peildatum))
35        
36        {
37            # bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
38            ?locatie onz-g:partOf* ?vestiging_uri .
39            ?vestiging_uri 
40                a onz-org:Vestiging ;
41                onz-g:identifiedBy ?vest_nr.
42            ?vest_nr a onz-org:Vestigingsnummer ;
43                onz-g:hasDataValue ?vestiging .
44        } UNION {
45            #Includeer ook de organisatie als geheel en label deze als vestiging
46            ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
47            ?organisatie_uri 
48                a onz-g:Business ;
49                rdfs:label ?organisatie .
50            BIND(CONCAT('Totaal ',?organisatie) AS ?vestiging)
51        }
52        # Als contract voor bepaalde tijd is, geef variabele bepaald de waarde 1
53        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBepaaldeTijd, 1, 0) AS ?bepaald)
54    }
55}
56GROUP BY ?vestiging
57ORDER BY ?vestiging
58