3.1.5 Percentage arbeidsovereenkomsten voor bepaalde tijd op 1-1-2024

Concepten

• Arbeidsovereenkomst bepaalde tijd
• Arbeidsovereenkomst onbepaalde tijd
• Bedrijf
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1
2# Indicator: Zorgkantoren 3.1
3# Parameters: -
4# Ontologie: versie 2.0.0 of nieuwer
5
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13	?vestiging
14    (SUM(?bepaald) AS ?aantal_bepaalde_tijd)
15    (COUNT(?personeel) AS ?totaal)
16    (?aantal_bepaalde_tijd/?totaal * 100 AS ?percentage_bepaalde_tijd)
17{
18    SELECT DISTINCT
19        ?vestiging
20        ?personeel
21        ?bepaald
22    {     
23        # definieer peildatum
24        BIND("2024-01-01"^^xsd:date AS ?peildatum)
25
26        # selecteer personen met arbeidsovereenkomst (on)bepaalde tijd
27        VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomstBepaaldeTijd onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd}
28        ?arbeidsovereenkomst a ?type_overeenkomst ;
29            onz-g:startDatum ?start_overeenkomst ;
30            onz-g:isAbout ?locatie ;
31            onz-pers:heeftOpdrachtnemer ?personeel .
32        OPTIONAL {?arbeidsovereenkomst onz-g:eindDatum ?eind_overeenkomst}
33            
34        # filter op peildatum
35        FILTER (?start_overeenkomst <= ?peildatum && (!BOUND(?eind_overeenkomst) || ?eind_overeenkomst >= ?peildatum))
36        
37        {
38            # bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
39            ?locatie onz-g:partOf* ?vestiging_uri .
40            ?vestiging_uri 
41                a onz-org:Vestiging ;
42                onz-g:identifiedBy ?vest_nr.
43            ?vest_nr a onz-org:Vestigingsnummer ;
44                onz-g:hasDataValue ?vestiging .
45        } UNION {
46            #Includeer ook de organisatie als geheel en label deze als vestiging
47            ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
48            ?organisatie_uri 
49                a onz-g:Business ;
50                rdfs:label ?organisatie .
51            BIND(CONCAT('Totaal ',?organisatie) AS ?vestiging)
52        }
53        # Als contract voor bepaalde tijd is, geef variabele bepaald de waarde 1
54        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBepaaldeTijd, 1, 0) AS ?bepaald)
55    }
56}
57GROUP BY ?vestiging
58ORDER BY ?vestiging
59