Let op: dit is een oudere versie van deze publicatie. Ga naar de laatste versie

Uitwisselprofiel Zorgkantoren Inkoopondersteuning en beleidsontwikkeling

10.1.0 Aantal leerlingen op een peildatum

Concepten

Relaties

Eigenschappen

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
3PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
4PREFIX onz-org: <http://purl.org/ozo/onz-org#>
5PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
6PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8
9SELECT 
10    ?Vestiging 
11    (COUNT (DISTINCT ?persoon) AS ?Aantal_BBL)
12{
13    #Bepaal de peildatum
14    BIND($(peildatum) AS ?peildatum)
15    
16    #Selecteer alle personeelsleden met een BBL overeenkomst binnen de meetperiode
17    ?persoon
18        a onz-g:Human ;
19        ^onz-pers:heeftOpdrachtnemer ?overeenkomst .
20    ?overeenkomst
21        a onz-pers:ArbeidsOvereenkomstBBL ;
22        onz-g:isAbout ?functie ;
23        onz-g:isAbout ?locatie ;
24        onz-g:startDatum ?start_overeenkomst .
25        OPTIONAL {?overeenkomst onz-g:eindDatum ?eind_overeenkomst}
26        FILTER (?start_overeenkomst <= ?peildatum && ((?eind_overeenkomst >= ?peildatum)||(!BOUND(?eind_overeenkomst))))
27
28    #Bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
29    {
30        ?locatie onz-g:partOf* ?vestiging_uri .
31        ?vestiging_uri 
32            a onz-org:Vestiging ;
33            onz-g:identifiedBy ?vest_nr.
34        ?vest_nr
35            a onz-org:Vestigingsnummer ;
36            onz-g:hasDataValue ?Vestiging .
37    } UNION {
38        #Includeer ook de organisatie als geheel en label deze als vestiging
39        ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
40        ?organisatie_uri 
41            a onz-g:Business ;
42            rdfs:label ?Organisatie .
43        BIND(CONCAT('Totaal ',?Organisatie) AS ?Vestiging)
44    }
45} 
46GROUP BY ?Vestiging
47
Terug naar: 9.1.5 Aantal vrijwilligers Q1 2024

Heb je feedback?

Loopt u tegen een issue of vraag aan bij het KIK-V product? Neem dan contact met ons op!