15.4.3.0 Aantal cliënten met een Wlz-indicatie met zorgprofiel VV per leveringsvorm

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.3.0
2# Parameters: 
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT 
12		?vestiging        
13        (SUM(?verblijf) as ?aantal_verblijf)
14        (SUM(?vpt) as ?aantal_vpt)
15        (SUM(?mpt) as ?aantal_mpt)
16        (SUM(?pgb) as ?aantal_pgb)   
17WHERE
18{
19        BIND ($(peildatum) AS ?peildatum)
20    	
21    	VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9VV onz-zorg:10VV }
22
23        #selecteer de zorgprocessen die voldoen aan de inclusiecriteria
24        ?zorgproces
25            a onz-zorg:NursingProcess ;
26            onz-g:definedBy ?indicatie ;
27            onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie ; # locatie bevat niet alleen vestigingen
28            onz-g:startDatum ?start_zorgproces .
29            OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
30            FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces))))   
31        {
32            ?locatie 
33                a onz-org:Vestiging ;
34                onz-g:identifiedBy ?vest_nr.
35            	?vest_nr a onz-org:Vestigingsnummer ;
36                     onz-g:hasDataValue ?vestiging .
37        } UNION {
38            #Includeer ook de organisatie als geheel en label deze als vestiging
39            ?locatie onz-org:vestigingVan ?organisatie_uri .
40            ?organisatie_uri 
41                a onz-g:Business ;
42                rdfs:label ?Organisatie .
43            BIND(CONCAT('Totaal ',?Organisatie) AS ?vestiging)
44        }
45
46    	#selecteer de bijbehorende indicatie, om unieke clienten te kunnen bepalen
47        ?indicatie
48        	a onz-zorg:WlzIndicatie ;
49         	onz-g:hasPart ?zorgprofiel ;
50            onz-g:hasPart ?lv ;
51            onz-g:isAbout ?client .
52    	?client a onz-g:Human .
53        ?lv
54            a onz-zorg:Leveringsvorm ;
55            rdfs:label ?leveringsvorm_label ;
56
57        #Per financieringsstroom
58        BIND(IF(?lv = onz-zorg:instelling, 1, 0) AS ?verblijf)
59        BIND(IF(?lv = onz-zorg:vpt, 1, 0) AS ?vpt)
60        BIND(IF(?lv = onz-zorg:mpt, 1, 0) AS ?mpt)
61    	BIND(IF(?lv = onz-zorg:pgb, 1, 0) AS ?pgb)
62} 
63GROUP BY ?vestiging
64ORDER BY ?vestiging
65