Uitwisselprofiel Zorgkantoren Inkoopondersteuning en beleidsontwikkeling

Versie:

Publicatiedatum:27-06-2024

Inwerkingtreding:01-10-2024




Bekijk bron...

1.2.2 Aantal personeelsleden op 1-4-2023

Concepten

Relaties

Eigenschappen

SPARQL query

Code gekopieerd

...

Kopieer naar klembord

1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
3PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
4PREFIX onz-org: <http://purl.org/ozo/onz-org#>
5PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
6PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8
9SELECT 
10    ?Vestiging 
11    (SUM(?zorg_boolean) AS ?Zorg) 
12    (COUNT(?persoon) - SUM(?zorg_boolean) AS ?Niet_zorg)
13    (COUNT(?persoon) AS ?Totaal) 
14{
15    {
16        SELECT ?persoon ?Vestiging (MAX(?zorgfunctie) AS ?zorg_boolean)
17        {
18            #Bepaal de peildatum
19            BIND("2023-04-01"^^xsd:date AS ?peildatum)
20            
21            #Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
22            VALUES ?personeels_overeenkomst 
23      		{ 
24        		onz-pers:ArbeidsOvereenkomst
25        		onz-pers:OproepOvereenkomst
26        		onz-pers:UitzendOvereenkomst
27        		onz-pers:InhuurOvereenkomst
28      		}
29            ?functie 
30                    a onz-g:OccupationalPositionRole ;
31                    onz-g:startDatum ?start_functie .
32            OPTIONAL {?functie a onz-g:OccupationalPositionRole ; 
33                           onz-g:eindDatum ?eind_functie}
34            FILTER(?start_functie <= ?peildatum && ((?eind_functie >= ?peildatum) || (!BOUND(?eind_functie))))
35            
36            # Selecteer alle personeelsleden (personen met een arbeids-, oproep,- uitzend,- of inhuurovereenkomst) binnen de meetperiode
37            ?overeenkomst
38                onz-g:isAbout ?functie ;
39                a ?personeels_overeenkomst ;
40                onz-pers:heeftOpdrachtnemer ?persoon ;
41                onz-g:isAbout ?locatie .
42            ?persoon
43                a onz-g:Human .
44      		?locatie onz-g:partOf* ?vestiging_uri .
45
46            #Bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
47            {               
48                ?vestiging_uri 
49                    a onz-org:Vestiging ;
50                    onz-g:identifiedBy ?vest_nr.
51                ?vest_nr
52                    a onz-org:Vestigingsnummer ;
53                    onz-g:hasDataValue ?Vestiging .
54            } UNION {
55                #Includeer ook de organisatie als geheel en label deze als vestiging
56                ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
57                ?organisatie_uri 
58                    a onz-g:Business ;
59                    rdfs:label ?Organisatie .
60                BIND(CONCAT('Totaal ',?Organisatie) AS ?Vestiging)
61            }
62            
63            #Bepaal of de functie op de overeenkomst van het type ZorgverlenerFunctie is
64            ?functie a ?type_functie .
65            BIND(IF(?type_functie = onz-pers:ZorgverlenerFunctie, 1, 0) AS ?zorgfunctie)
66        } 
67        GROUP BY ?persoon ?Vestiging
68    }
69} GROUP BY ?Vestiging
70

Heb je feedback?

Loopt u tegen een issue of vraag aan bij het KIK-V product? Neem dan contact met ons op!