Let op: dit is een oudere versie van deze publicatie. Ga naar de laatste versie

Uitwisselprofiel Zorgkantoren Inkoopondersteuning en beleidsontwikkeling

9.1.0 Aantal vrijwilligers per kwartaal

Concepten

Relaties

Eigenschappen

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
3PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
4PREFIX onz-org: <http://purl.org/ozo/onz-org#>
5PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
6PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8
9SELECT 
10    ?Vestiging 
11    (SUM(?zorg_boolean) AS ?Zorg) 
12    (COUNT(?persoon) - SUM(?zorg_boolean) AS ?Niet_zorg)
13    (COUNT(?persoon) AS ?Totaal) 
14{
15        SELECT ?persoon ?Vestiging (MAX(?zorgfunctie) AS ?zorg_boolean)
16        {
17            #Bepaal een meetperiode van drie maanden, startend vanaf een in te vullen datum
18            BIND($(start_periode) AS ?start_periode)
19            BIND(?start_periode + "P3M"^^xsd:duration - "P1D"^^xsd:duration AS ?eind_periode)
20            
21            #Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
22            VALUES ?personeels_overeenkomst 
23      		{ 
24        		onz-pers:VrijwilligersOvereenkomst
25      		}
26
27            #Selecteer alle personeelsleden (personen met een arbeids-, oproep,- uitzend,- of inhuurovereenkomst) binnen de meetperiode
28            ?persoon
29                a onz-g:Human ;
30                ^onz-pers:heeftOpdrachtnemer ?overeenkomst .
31            ?overeenkomst
32                a ?personeels_overeenkomst ;
33                onz-g:isAbout ?functie ;
34                onz-g:isAbout ?locatie ;
35                onz-g:startDatum ?start_overeenkomst .
36                OPTIONAL {?overeenkomst onz-g:eindDatum ?eind_overeenkomst}
37                FILTER(?start_overeenkomst <= ?eind_periode && ((?eind_overeenkomst >= ?start_periode) || (!BOUND(?eind_overeenkomst))))
38
39            #Bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
40            {
41                ?locatie onz-g:partOf* ?vestiging_uri .
42                ?vestiging_uri 
43                    a onz-org:Vestiging ;
44                    onz-g:identifiedBy ?vest_nr.
45                ?vest_nr a onz-org:Vestigingsnummer ;
46                    onz-g:hasDataValue ?Vestiging .
47            } UNION {
48                #Includeer ook de organisatie als geheel en label deze als vestiging
49                ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
50                ?organisatie_uri 
51                    a onz-g:Business ;
52                    rdfs:label ?Organisatie .
53                BIND(CONCAT('Totaal ',?Organisatie) AS ?Vestiging)
54            }
55            
56            #Bepaal of de functie op de overeenkomst van het type ZorgverlenerFunctie is
57            ?functie 
58                a onz-g:OccupationalPositionRole ;
59                a ?type_functie .
60            BIND(IF(?type_functie = onz-pers:ZorgverlenerFunctie, 1, 0) AS ?zorgfunctie)
61        } 
62        GROUP BY ?persoon ?Vestiging
63} GROUP BY ?Vestiging
64
Terug naar: 8.2.5 Percentage kosten personeel niet in loondienst (PNIL) Q1 2024

Heb je feedback?

Loopt u tegen een issue of vraag aan bij het KIK-V product? Neem dan contact met ons op!